File Coverage

blib/lib/Net/TinyIp/Address.pm

Criterion	Covered	Total	%
statement	24	56	42.8
branch	0	6	0.0
condition	0	3	0.0
subroutine	8	15	53.3
pod	2	7	28.5
total	34	87	39.0

package Net::TinyIp::Address;
use strict;
use warnings;
use base "Math::BigInt";
use Carp qw( croak );
use Net::TinyIp::Address::v4;
use Net::TinyIp::Address::v6;

use overload q{""} => \&human_readable;

sub from_bin {
    my $class   = shift;
    my $big_int = $class->SUPER::new( @_ );

    return bless $big_int, $class;
}

sub from_hex {
    my $class   = shift;
    my $big_int = $class->SUPER::new( @_ );

    return bless $big_int, $class;
}

sub from_cidr {
    my $class  = shift;
    my $prefix = shift;
    my $length = $class->get( "bits_length" );
    my $self   = $class->from_bin( "0b1" );

    $self = ( $self << $prefix ) - 1;
    $self = $self << ( $length - $prefix );

    return $self;
}

sub get {
    my $class = shift;
    my $what  = uc shift;

    $class = ref $class
        if ref $class;

    my $ret = do {
        no strict "refs";
        ${ "${class}::$what" };
    }
        or croak "No $what exists.";

    return $ret;
}

sub version { shift->get( "version" ) }

sub cidr {
    my $self = shift;
    ( my $bin_str = $self->as_bin ) =~ s{\A 0b }{}msx;

    return 0 if length( $bin_str ) < $self->get( "bits_length" );
    return length sprintf "%s", $bin_str =~ m{\A (1+) }msx;
}

sub human_readable {
    my $self   = shift;
    my $format = shift || $self->get( "block_format" );

    ( my $bin_str = $self->as_bin ) =~ s{\A 0b }{}msx;
    $bin_str = "0" x ( $self->get( "bits_length" ) - length $bin_str ) . $bin_str;

    my $bits_per_block = $self->get( "bits_per_block" );

    return join $self->get( "separator" ), map { sprintf $format, eval "0b$_" } ( $bin_str =~ m{ (\d{$bits_per_block}) }gmsx );
}

1;
__END__