File Coverage

blib/lib/Net/SSH/Perl/Cipher/CBC.pm

Criterion	Covered	Total	%
statement	29	29	100.0
branch			n/a
condition	2	3	66.6
subroutine	4	4	100.0
pod	0	3	0.0
total	35	39	89.7

# $Id: CBC.pm,v 1.6 2008/09/24 19:21:21 turnstep Exp $

# This code is based in part on the Systemics Crypt::CBC.
# Parts copyright (C) 1995, 1996 Systemics Ltd (http://www.systemics.com/)
# All rights reserved.

package Net::SSH::Perl::Cipher::CBC;
use strict;

sub new {
    my($class, $ciph, $iv) = @_;
    bless {
        cipher => $ciph,
        iv     => $iv || ("\0" x $ciph->blocksize),
    }, $class;
}

sub encrypt {
    my $cbc = shift;
    my $data = shift;

    my $retval = "";
    my $iv = $cbc->{iv};
    my $ciph = $cbc->{cipher};
    my $size = $ciph->blocksize;

    while (length $data) {
        my $in = substr($data, 0, $size, '') ^ $iv;
        $iv = $ciph->encrypt($in);
        $retval .= $iv;
    }

    $cbc->{iv} = $iv;
    $retval;
}

sub decrypt {
    my $cbc = shift;
    my $data = shift;

    my $retval = "";
    my $iv = $cbc->{iv};
    my $ciph = $cbc->{cipher};
    my $size = $ciph->blocksize;

    while (length $data) {
        my $in = substr($data, 0, $size, '');
        $retval .= $ciph->decrypt($in) ^ $iv;
        $iv = $in;
    }

    $cbc->{iv} = $iv;
    $retval;
}

1;
__END__