File Coverage

blib/lib/Net/SMS/CDYNE.pm

Criterion	Covered	Total	%
statement	20	78	25.6
branch	0	20	0.0
condition	0	16	0.0
subroutine	7	16	43.7
pod	0	9	0.0
total	27	139	19.4

package Net::SMS::CDYNE;

use 5.008_001;
our $VERSION = '0.14';

use Any::Moose;
use Any::Moose 'X::NonMoose';
use XML::Simple;
use Carp qw/croak cluck/;
use Net::SMS::CDYNE::Response;
use Encode;

extends 'REST::Client';

has 'debug' => (
    is => 'rw',
    isa => 'Bool',
    default => 0,
);

has 'api_key' => (
    is => 'rw',
    isa => 'Str',
    required => 1,
);

sub do_cdyne_request {
    my ($self, $method, $uri, $args, $body) = @_;

    croak "URI is required" unless $uri;

    $args ||= {};
    $args->{LicenseKey} ||= $self->api_key;

    # build request
    my $headers = {};
    my $args_encoded = $args && %$args ? $self->buildQuery($args) : '';
    $args_encoded =~ s/^(\?)//;
    if (lc $method eq 'get') {
        $uri .= '?' . $args_encoded;
    } else {
        $headers->{'Content-Type'} = 'text/xml';
    }

    # encode body
    $body = encode_utf8($body)
        if defined $body;

    warn "Request: $uri\n" if $self->debug;

    $self->request($method, $uri, $body, $headers);

    my $response_code = $self->responseCode;
    my $content = $self->responseContent;

    if (! $response_code || index($response_code, '2') != 0) {
        warn "CDYNEv2 request ($uri) failed with code $response_code: " . $content .
        "\n\nRequest body was: $body\n";

        # return empty response
        return Net::SMS::CDYNE::Response->new(response_code => $response_code);
    }

    warn "\nResponse: $content\n" if $self->debug;

    # attempt to parse response XML
    my $resp_obj = eval { XMLin($content) };
    warn "Failed parsing response: $content ($@)" unless $resp_obj;

    # if we do an advanced send, we get an array of responses.
    # since we only handle sending one message at a time, we can just grab the first response.
    $resp_obj = $resp_obj->{SMSResponse} if $resp_obj->{SMSResponse};

    my $ret = {
        response_code => $response_code,
        %$resp_obj,
    };

    return bless $ret, 'Net::SMS::CDYNE::Response';
}

# takes a phone number, returns a structure of info
sub phone_verify {
    my ($self, $phone_number) = @_;

    my $uri = 'http://ws.cdyne.com/phoneverify/phoneverify.asmx/CheckPhoneNumber';
    return $self->do_cdyne_request('GET', $uri, { PhoneNumber => $phone_number });
}
# $ curl 'http://ws.cdyne.com/phoneverify/phoneverify.asmx/CheckPhoneNumber?PhoneNumber=17575449510&LicenseKey=XXXXX'
#
#
#   LEVEL 3 COMM - VA
#   true
#   Assigned to a code holder for normal use.
#   VA
#   NRFOLKZON2
#   8825
#   17575449510
#   7575449510
#   CHSKVAAY0MD
#
#   United States
#   CHSKVAAYDS0
#   CLEC - (Competitive Local Exchange Carrier)
#   252
#   CLEC - (Competitive Local Exchange Carrier)
#
#   05/24/2001
#   PARKSLEY
#
#   VA
#   23421
#   EST
#   37.7790
#   -75.6343
#   false
#   7576559199
#

sub simple_sms_send_with_postback {
    my ($self, %args) = @_;

    my $uri = 'https://sms2.cdyne.com/sms.svc/SecureREST/SimpleSMSsendWithPostback';
    return $self->do_cdyne_request('GET', $uri, \%args);
}

sub simple_sms_send {
    my ($self, %args) = @_;

    my $uri = 'https://sms2.cdyne.com/sms.svc/SecureREST/SimpleSMSsend';
    return $self->do_cdyne_request('GET', $uri, \%args);
}

# takes AssignedDID
sub advanced_sms_send {
    my ($self, %args) = @_;

    my $uri = 'https://sms2.cdyne.com/sms.svc/SecureREST/AdvancedSMSsend';

    $args{LicenseKey} ||= $self->api_key;
    my $nums = delete $args{PhoneNumbers};
    $nums = [delete $args{PhoneNumber}] if $args{PhoneNumber};
    my $refid = delete $args{ReferenceID} || '';

    my @subdoc = ();
    foreach my $num (@$nums){
        push(@subdoc,
            {
                string => [
                    {
                        xmlns => 'http://schemas.microsoft.com/2003/10/Serialization/Arrays',
                        content => $num,
                    },
                ]
            }
        );
    }

    my $doc = {
        SMSAdvancedRequest => {
            xmlns => 'http://schemas.datacontract.org/2004/07/SmsWS',
            LicenseKey => [ delete $args{LicenseKey} ],
            SMSRequests => [
                {
                    SMSRequest => [
                        {
                            xmlns => "http://sms2.cdyne.com",
                            Message => [ delete $args{Message} ],
                            AssignedDID => [ delete $args{AssignedDID} ],
                            StatusPostBackURL => [ delete $args{StatusPostBackURL} ],
                            ReferenceID => [ $refid ],
                            PhoneNumbers => \@subdoc
                        },
                    ],
                },
            ],
        },
    };

    my $body = XML::Simple::XMLout($doc, KeepRoot => 1, ContentKey => 'content');

    return $self->do_cdyne_request('POST', $uri, \%args, $body);
}

sub get_unread_incoming_messages {
    my ($self, %args) = @_;

    my $uri = 'https://sms2.cdyne.com/sms.svc/SecureREST/GetUnreadIncomingMessages';
    return $self->do_cdyne_request('GET', $uri, \%args);
}

sub get_message_status_by_reference_id {
    my ($self, %args) = @_;

    my $uri = 'https://sms2.cdyne.com/sms.svc/SecureREST/GetMessageStatusByReferenceID';
    return $self->do_cdyne_request('GET', $uri, \%args);
}

sub get_message_status {
    my ($self, %args) = @_;

    my $uri = 'https://sms2.cdyne.com/sms.svc/SecureREST/GetMessageStatus';
    return $self->do_cdyne_request('GET', $uri, \%args);
}

sub cancel_message {
    my ($self, %args) = @_;

    my $uri = 'https://sms2.cdyne.com/sms.svc/SecureREST/CancelMessage';
    return $self->do_cdyne_request('GET', $uri, \%args);
}

1;

__END__