File Coverage

blib/lib/Net/SMS/ASPSMS.pm

Criterion	Covered	Total	%
statement	16	18	88.8
branch			n/a
condition			n/a
subroutine	6	6	100.0
pod			n/a
total	22	24	91.6

package Net::SMS::ASPSMS;

use warnings;
use strict;
use Carp;

use LWP::UserAgent;
use Net::SMS::ASPSMS::XML;
use XML::DOM;
use Encode qw(decode encode);

our $VERSION = '0.1.6';

use List::Util qw(shuffle);

my %actions = (
    send_random_logo               => 'SendRandomLogo',
    send_text_sms                  => 'SendTextSMS',
    send_picture_message           => 'SendPictureMessage',
    send_logo                      => 'SendLogo',
    send_group_logo                => 'SendGroupLogo',
    send_ringtone                  => 'SendRingtone',
    inquire_delivery_notifications => 'InquireDeliveryNotifications',
    show_credits                   => 'ShowCredits',
    send_vcard                     => 'SendVCard',
    send_binary_data               => 'SendBinaryData',
    send_wap_push_sms              => 'SendWAPPushSMS',
    send_originator_unlock_code    => 'SendOriginatorUnlockCode',
    unlock_originator              => 'UnlockOriginator',
    check_originator_authorization => 'CheckOriginatorAuthorization'
);

sub new {
    my $this = shift;
    my $class = ref($this) || $this;
    my $self = {};
    bless $self, $class;
    $self->{xml} = new Net::SMS::ASPSMS::XML(@_);
    $self->{result} = {};
    return $self;
}

sub _send {
    my $self = shift;
    my $message = $self->{xml}->as_string;
    my @urls = shuffle (qw(xml1.aspsms.com:5061 xml1.aspsms.com:5098
                           xml2.aspsms.com:5061 xml2.aspsms.com:5098));
    my $ua = LWP::UserAgent->new (timeout => 10);
    foreach my $url (@urls) {
        my $req = HTTP::Request->new(POST => "http://$url/xmlsvr.asp");
        $req->content(encode("iso-8859-1", $message));
        my $res = $ua->request($req);
        if ($res->is_success) {
            $self->{status_line} = $res->status_line;
            $self->{result} = {};
            my $parser = new XML::DOM::Parser;
            my $doc = $parser->parse($res->content);
            my $node;
            foreach (qw(ErrorCode ErrorDescription CreditsUsed Credits
                ParserErrorCode ParserErrorDescription ParserErrorFilePos
                ParserErrorLine ParserErrorLinePos ParserErrorSrcText)) {
                if ($node = $doc->getElementsByTagName($_)->item(0)) {
                    $self->{result}->{$_} =
                        $node->getFirstChild->getNodeValue;
                }
            }
            my $dn = $doc->getElementsByTagName("DeliveryNotification")
                ->item(0);
            if ($dn) {
                $self->{result}->{DeliveryNotification} = {};
                foreach (qw(TransRefNumber DeliveryStatus SubmissionDate
                    NotificationDate ReasonCode)) {
                     if ($node = $dn->getElementsByTagName($_)->item(0)) {
                        $self->{result}->{DeliveryNotification}->{$_} =
                            $node->getFirstChild->getNodeValue;
                    }
                }
            }
            last
        }
    }
}

sub params {
    my $self = shift;
    $self->{xml}->initialize(@_);
}

sub result {
    my $self = shift;
    return $self->{result};
}

sub AUTOLOAD {
    my $self = shift or return undef;
    (my $method = our $AUTOLOAD) =~ s{.*::}{};
    return if $method eq 'DESTROY';

    if (exists $actions{$method}) {
        $self->{xml}->initialize(@_);
        $self->{xml}->action($actions{$method});
        $self->_send;
    }
}

1;
__END__