File Coverage

blib/lib/Net/NBName/NodeStatus.pm

Criterion	Covered	Total	%
statement	30	37	81.0
branch	2	2	100.0
condition			n/a
subroutine	7	8	87.5
pod	3	4	75.0
total	42	51	82.3

use strict;
use warnings;

package Net::NBName::NodeStatus;

use Net::NBName::NodeStatus::RR;

use vars '$VERSION';
$VERSION = "0.26";

sub new
{
    my $class = shift;
    my $resp = shift;

    my @rr = ();
    my $mac_address = "";

    # Don't attempt to extract any names or the mac address
    # if the response is truncated
    if (length($resp) > 56) {
        my $num_names = unpack("C", substr($resp, 56));
        my $name_data = substr($resp, 57);

        for (my $i = 0; $i < $num_names; $i++) {
            my $rr_data = substr($name_data, 18*$i, 18);
            push @rr, Net::NBName::NodeStatus::RR->new($rr_data);
        }

        $mac_address = join "-", map { sprintf "%02X", $_ }
            unpack("C*", substr($name_data, 18 * $num_names, 6));
    }

    my $self = {'names' => \@rr, 'mac_address' => $mac_address};
    bless $self, $class;
    return $self;
}

sub as_string
{
    my $self = shift;

    my $string = "";
    for my $rr (@{$self->{names}}) {
        $string .= $rr->as_string;
    }
    $string .= "MAC Address = " . $self->{mac_address} . "\n";
    return $string;
}

sub names { return @{$_[0]->{'names'}}; }
sub mac_address { return $_[0]->{'mac_address'}; }

1;

__END__