File Coverage

blib/lib/Net/Google/Blogger.pm

Criterion	Covered	Total	%
statement	16	18	88.8
branch			n/a
condition			n/a
subroutine	6	6	100.0
pod			n/a
total	22	24	91.6

package Net::Google::Blogger;

use warnings;
use strict;

use Any::Moose;
use LWP::UserAgent;
use HTTP::Request::Common;
use XML::Simple;
use Data::Dumper;

use Net::Google::Blogger::Blog;


our $VERSION = '0.09';

has login_id   => ( is => 'ro', isa => 'Str', required => 1 );
has password   => ( is => 'ro', isa => 'Str', required => 1 );

has blogs => (
    is         => 'ro',
    isa        => 'ArrayRef[Net::Google::Blogger::Blog]',
    lazy_build => 1,
    auto_deref => 1,
);

has ua => (
    builder    => sub { LWP::UserAgent->new },
    lazy_build => 1,
    is         => 'ro',
);

__PACKAGE__->meta->make_immutable;


sub BUILD {
    ## Authenticates with Blogger.
    my $self = shift;

    my $response = $self->ua->post(
        'https://www.google.co.uk/accounts/ClientLogin',
        {
            Email       => $self->login_id,
            Passwd      => $self->password,
            service     => 'blogger',
        }
    );

    unless ($response->is_success) {
        my $error_msg = ($response->content =~ /\bError=(.+)/)[0] || 'Google error message unavailable';
        die 'HTTP error when trying to authenticate: ' . $response->status_line . " ($error_msg)";
    }

    my ($auth_token) = $response->content =~ /\bAuth=(.+)/
        or die 'Authentication token not found in the response: ' . $response->content;

    $self->ua->default_header(Authorization => "GoogleLogin auth=$auth_token");
    $self->ua->default_header(Content_Type => 'application/atom+xml');
}


sub _build_blogs {
    ## Populates 'blogs' property with list of instances of Net::Google::Blogger::Blog.
    my $self = shift;

    my $response = $self->http_get('http://www.blogger.com/feeds/default/blogs');
    my $response_tree = XML::Simple::XMLin($response->content, ForceArray => 1);

    return [
        map Net::Google::Blogger::Blog->new(
                source_xml_tree => $_,
                blogger         => $self,
            ),
            @{ $response_tree->{entry} }
   ];
}


sub http_put {
    ## Executes a PUT request using configured user agent instance.
    my $self = shift;
    my ($url, $content) = @_;

    my $request = HTTP::Request->new(PUT => $url, $self->ua->default_headers, $content);
    return $self->ua->request($request);
}


sub http_get {
    ## Executes a GET request.
    my $self = shift;
    my @req_args = @_;

    return $self->ua->get(@req_args);
}


sub http_post {
    ## Executes a POST request.
    my $self = shift;
    my @args = @_;

    return $self->ua->request(HTTP::Request::Common::POST(@args));
}


__END__