File Coverage

blib/lib/Net/Frame/Layer/OSPF/DatabaseDesc.pm

Criterion	Covered	Total	%
statement	29	52	55.7
branch	4	18	22.2
condition	0	3	0.0
subroutine	7	9	77.7
pod	5	5	100.0
total	45	87	51.7

#
# $Id: DatabaseDesc.pm,v 1.4 2007/03/13 18:14:43 gomor Exp $
#
package Net::Frame::Layer::OSPF::DatabaseDesc;
use strict;
use warnings;

use Net::Frame::Layer qw(:consts :subs);
our @ISA = qw(Net::Frame::Layer);

our @AS = qw(
   interfaceMtu
   options
   flags
   ddSequenceNumber
   lls
);
our @AA = qw(
   lsaList
);
__PACKAGE__->cgBuildIndices;
__PACKAGE__->cgBuildAccessorsScalar(\@AS);
__PACKAGE__->cgBuildAccessorsArray (\@AA);

use Net::Frame::Layer::OSPF qw(:consts);
require Net::Frame::Layer::OSPF::Lsa;

sub new {
   shift->SUPER::new(
      interfaceMtu     => 1500,
      options          => 0,
      flags            => 0,
      ddSequenceNumber => 1,
      lsaList          => [],
      @_,
   );
}

sub getLength {
   my $self = shift;
   my $len = 8;
   for ($self->lsaList) {
      $len += $_->getLength;
   }
   if ($self->lls) {
      $len += $self->lls->getLength;
   }
   $len;
}

sub pack {
   my $self = shift;

   my $raw = $self->SUPER::pack('nCCN',
      $self->interfaceMtu, $self->options, $self->flags,
      $self->ddSequenceNumber,
   ) or return undef;

   for ($self->lsaList) {
      $raw .= $_->pack or return undef;
   }

   if ($self->lls) {
      $raw .= $self->lls->pack or return undef;
   }

   $self->raw($raw);
}

sub unpack {
   my $self = shift;

   my ($interfaceMtu, $options, $flags, $ddSequenceNumber, $payload) =
      $self->SUPER::unpack('nCCN a*', $self->raw)
         or return undef;

   $self->interfaceMtu($interfaceMtu);
   $self->options($options);
   $self->flags($flags);
   $self->ddSequenceNumber($ddSequenceNumber);

   my @lsaList = ();
   if ($payload) {
      my $count;
      while ($payload || (++$count > 100)) {
         my $lsa = Net::Frame::Layer::OSPF::Lsa->new(
            raw  => $payload,
            full => 0,
         ) or last;
         $lsa->unpack;
         $payload = $lsa->payload;
         push @lsaList, $lsa;
      }
   }

   $self->lsaList(\@lsaList);

   $self->payload($payload);

   $self;
}

sub print {
   my $self = shift;

   my $l = $self->layer;
   my $buf = sprintf
      "$l: interfaceMtu:%d  options:0x%02x  flags:0x%02x\n".
      "$l: ddSequenceNumber:%d",
         $self->interfaceMtu,
         $self->options,
         $self->flags,
         $self->ddSequenceNumber,
   ;

   for ($self->lsaList) {
      $buf .= "\n".$_->print;
   }

   if ($self->lls) {
      $buf .= "\n".$self->lls->print;
   }

   $buf;
}

1;

__END__