File Coverage

blib/lib/Net/Frame/Layer/LLTD/RecveeDesc.pm

Criterion	Covered	Total	%
statement	24	28	85.7
branch	2	4	50.0
condition			n/a
subroutine	6	8	75.0
pod	5	5	100.0
total	37	45	82.2

#
# $Id: RecveeDesc.pm 12 2015-01-14 06:29:59Z gomor $
#
package Net::Frame::Layer::LLTD::RecveeDesc;
use strict; use warnings;

use Net::Frame::Layer qw(:consts :subs);
our @ISA = qw(Net::Frame::Layer);

our @AS = qw(
   type
   realSourceAddress
   sourceAddress
   destinationAddress
);
__PACKAGE__->cgBuildIndices;
__PACKAGE__->cgBuildAccessorsScalar(\@AS);

sub new {
   shift->SUPER::new(
      type               => 0,
      realSourceAddress  => 'ff:ff:ff:ff:ff:ff',
      sourceAddress      => 'ff:ff:ff:ff:ff:ff',
      destinationAddress => 'ff:ff:ff:ff:ff:ff',
      @_,
   );
}

sub getLength { 20 }

sub pack {
   my $self = shift;

   (my $realSourceAddress  = $self->realSourceAddress)  =~ s/://g;
   (my $sourceAddress      = $self->sourceAddress)      =~ s/://g;
   (my $destinationAddress = $self->destinationAddress) =~ s/://g;

   $self->raw($self->SUPER::pack('nH12H12H12',
      $self->type,
      $realSourceAddress,
      $sourceAddress,
      $destinationAddress,
   )) or return undef;

   $self->raw;
}

sub unpack {
   my $self = shift;

   my ($type, $realMac, $srcMac, $dstMac, $payload) =
      $self->SUPER::unpack('nH12H12H12 a*', $self->raw)
         or return undef;

   $self->type($type);
   $self->realSourceAddress(convertMac($realMac));
   $self->sourceAddress(convertMac($srcMac));
   $self->destinationAddress(convertMac($dstMac));

   $self->payload($payload);

   $self;
}

sub print {
   my $self = shift;

   my $l = $self->layer;
   sprintf
      "$l: type:%02x  realSourceAddress: %s\n".
      "$l: sourceAddress:      %s\n".
      "$l: destinationAddress: %s",
         $self->type,
         $self->realSourceAddress,
         $self->sourceAddress,
         $self->destinationAddress;
}

1;

__END__