File Coverage

blib/lib/Net/Frame/Layer/CDP/VoipVlanQuery.pm

Criterion	Covered	Total	%
statement	36	56	64.2
branch	8	28	28.5
condition	2	18	11.1
subroutine	8	10	80.0
pod	6	6	100.0
total	60	118	50.8

#
# $Id: VoipVlanQuery.pm 1640 2013-03-28 17:58:27Z VinsWorldcom $
#
package Net::Frame::Layer::CDP::VoipVlanQuery;
use strict; use warnings;

use Net::Frame::Layer qw(:consts :subs);
our @ISA = qw(Net::Frame::Layer);

our @AS = qw(
   type
   length
   data
   voipVlan
);
__PACKAGE__->cgBuildIndices;
__PACKAGE__->cgBuildAccessorsScalar(\@AS);

#no strict 'vars';

use Net::Frame::Layer::CDP::Constants qw(:consts);

sub new {
   shift->SUPER::new(
      type     => NF_CDP_TYPE_VOIP_VLAN_QUERY,
      length   => 5,
      data     => 1,
      voipVlan => '',
      @_,
   );
}

sub getLength {
   my $self = shift;

   my $length = 4;
   if (defined($self->data) && ($self->data ne '')) {
      $length += 1;
   }
   if (defined($self->voipVlan) && ($self->voipVlan ne '')) {
      $length += 2;
   }

   return $length;
}

sub pack {
   my $self = shift;

   my $raw = $self->SUPER::pack('nn',
      $self->type,
      $self->length,
   ) or return;

   if (defined($self->data) && ($self->data ne '')) {
      $raw .= $self->SUPER::pack('C',
         $self->data
      ) or return;
   }

   if (defined($self->voipVlan) && ($self->voipVlan ne '')) {
      $raw .= $self->SUPER::pack('n',
         $self->voipVlan
      ) or return;
   }

   return $self->raw($raw);
}

sub unpack {
   my $self = shift;

   my ($type, $length, $payload) =
      $self->SUPER::unpack('nn a*', $self->raw)
         or return;

   $self->type($type);
   $self->length($length);

   my $data;
   if ($length >= 5) {
      ($data, $payload) =
         $self->SUPER::unpack('C a*', $payload)
            or return;
      $self->data($data);
      my $voipVlan;
      if ($length >= 7) {
         ($voipVlan, $payload) =
            $self->SUPER::unpack('n a*', $payload)
               or return;
         $self->voipVlan($voipVlan);
      } else {
         $self->voipVlan('');
      }
   } else {
      $self->data('');
      $self->voipVlan('');
   }

   $self->payload($payload);

   return $self;
}

sub computeLengths {
   my $self = shift;

   my $length = 4;
   if (defined($self->data) && ($self->data ne '')) {
      $length += 1;
   }
   if (defined($self->voipVlan) && ($self->voipVlan ne '')) {
      $length += 2;
   }

   $self->length($length);

   return 1;
}

sub print {
   my $self = shift;

   my $l = $self->layer;
   my $buf = sprintf
      "$l: type:0x%04x  length:%d  data:%s  voipVlan:%s",
         $self->type, $self->length, $self->data, $self->voipVlan;

   return $buf;
}

1;

__END__