File Coverage

blib/lib/Net/Frame/Layer/CDP/IPNetPrefix.pm

Criterion	Covered	Total	%
statement	41	50	82.0
branch	5	10	50.0
condition			n/a
subroutine	8	10	80.0
pod	6	6	100.0
total	60	76	78.9

#
# $Id: IPNetPrefix.pm 1640 2013-03-28 17:58:27Z VinsWorldcom $
#
package Net::Frame::Layer::CDP::IPNetPrefix;
use strict; use warnings;

use Net::Frame::Layer qw(:consts :subs);
our @ISA = qw(Net::Frame::Layer);

our @AS = qw(
   type
   length
);
our @AA = qw(
   IpNetPrefix
);
__PACKAGE__->cgBuildIndices;
__PACKAGE__->cgBuildAccessorsScalar(\@AS);
__PACKAGE__->cgBuildAccessorsArray(\@AA);

#no strict 'vars';

use Net::Frame::Layer::CDP::Constants qw(:consts);

sub new {
   shift->SUPER::new(
      type        => NF_CDP_TYPE_IPNET_PREFIX,
      length      => 9,
      IpNetPrefix => ['127.0.0.1/8'],
      @_,
   );
}

sub getLength {
   my $self = shift;

   my $length = 4;
   $length += 5 for $self->IpNetPrefix;

   return $length
}

sub pack {
   my $self = shift;

   my $raw = $self->SUPER::pack('nn',
      $self->type,
      $self->length
   ) or return;

   for ($self->IpNetPrefix) {
      my ($prefix, $mask) = split /\//, $_;
      $raw .= $self->SUPER::pack('a4C',
         inetAton($prefix),
         $mask
      ) or return;
   }

   return $self->raw($raw);
}

sub unpack {
   my $self = shift;

   my ($type, $length, $tail) =
      $self->SUPER::unpack('nna*', $self->raw)
         or return;

   $self->type($type);
   $self->length($length);

   my $valLen = $length - 4;
   my ($IpNetPrefix, $payload) =
      $self->SUPER::unpack("a$valLen a*", $tail)
         or return;

   my @prefixList;
   for (1..$valLen/5) {
      my ($prefix, $mask) =
         $self->SUPER::unpack("a4C", $IpNetPrefix)
            or return;

      $prefix = inetNtoa($prefix);
      $prefix .= "/$mask";
      push @prefixList, $prefix;
      $IpNetPrefix = substr $IpNetPrefix, 5
   }

   $self->IpNetPrefix(\@prefixList);
   $self->payload($payload);

   return $self;
}

sub computeLengths {
   my $self = shift;

   my $length = 4;
   $length += 5 for $self->IpNetPrefix;
   $self->length($length);

   return 1;
}

sub print {
   my $self = shift;

   my $l = $self->layer;
   my $buf = sprintf
      "$l: type:0x%04x  length:%d",
         $self->type, $self->length;

   for ($self->IpNetPrefix) {
      $buf .= sprintf
      "\n$l: IpNetPrefix:%s",
         $_
   }

   return $buf;
}

1;

__END__