File Coverage

blib/lib/Net/Azure/CognitiveServices/Face/Base.pm

Criterion	Covered	Total	%
statement	40	61	65.5
branch	7	16	43.7
condition	1	9	11.1
subroutine	12	15	80.0
pod	7	7	100.0
total	67	108	62.0

package Net::Azure::CognitiveServices::Face::Base;
use strict;
use warnings;
use Class::Accessor::Lite (
    new => 1,
    ro  => [qw[access_key endpoint]],
);
use LWP::UserAgent;
use JSON;
use Carp;
use URI;
use HTTP::Request;

sub path {''};

sub uri {
    my ($self, $path, %query) = @_;
    my $uri = URI->new($self->endpoint);
    $uri->path($path ? join('/', $self->path, $path) : $self->path);
    if (keys %query) {
        $uri->query_form(%query);
    }
    $uri;
}

sub json {
    my $self = shift;
    $self->{json} ||= JSON->new->utf8(1);
    $self->{json};
}

sub agent {
    my $self = shift;
    $self->{agent} ||= LWP::UserAgent->new(agent => __PACKAGE__, timeout => 60);
    $self->{agent};
}

sub request {
    my ($self, $req) = @_;
    my $res;
    my $try = 0;
    while (1) {
        $res = $self->agent->request($req);
        $try++;
        if ($try > 10 || $res->code != 429) {
            last;
        }
        carp sprintf('Retry. Because API said %s', $res->content);
    }
    my $body;
    if ($res->content) {
        if ($res->content_type !~ /application\/json/) {
            croak($res->content);
        }
        $body = $self->json->decode($res->content);
    }
    if (!$res->is_success) {
        croak($body->{error}{message});
    }
    $body;
}

sub build_headers {
    my ($self, @headers) = @_;
    (
        "Content-Type"              => "application/json",
        "Ocp-Apim-Subscription-Key" => $self->access_key,
        @headers,
    );
}

sub build_request {
    my ($self, $method, $uri_param, $header, $hash) = @_;
    my $uri  = $self->uri(@$uri_param);
    my $body = $hash ? $self->json->encode($hash) : undef;
    my @headers = $self->build_headers(defined $header ? @$header : ());
    HTTP::Request->new($method => $uri, [@headers], $body);
}

1;

__END__