File Coverage

blib/lib/Net/Appliance/Phrasebook.pm

Criterion	Covered	Total	%
statement	54	54	100.0
branch	8	10	80.0
condition	2	3	66.6
subroutine	13	13	100.0
pod	1	1	100.0
total	78	81	96.3

package Net::Appliance::Phrasebook;
BEGIN {
  $Net::Appliance::Phrasebook::VERSION = '2.103642';
}

use strict;
use warnings FATAL => qw(all);

use base qw(Class::Data::Inheritable);

use Data::Phrasebook;
use List::Util qw(first);
use List::MoreUtils qw(after_incl);
use File::Basename;
use Symbol;
use Carp;

__PACKAGE__->mk_classdata('__phrasebook_file');
__PACKAGE__->mk_classdata('__families' => [
    ['FWSM3', 'FWSM', 'PIXOS', 'Cisco'],
    ['ASA', 'PIXOS7', 'PIXOS', 'Cisco'],
    ['Aironet', 'IOS', 'Cisco'],
    ['CATOS', 'Cisco'],
    ['JUNOS', 'Cisco'],
    ['HP', 'Cisco'],
    ['Nortel', 'Cisco'],
    ['ExtremeXOS', 'Cisco'],
]);

sub new {
    my $class = shift;
    my %args  = @_;

    croak "missing argument to Net::Appliance::Phrasebook::new"
        if not defined $args{platform};

    my ($data, $dict);

    # user's own phrasebook
    if (exists $args{source}) {
        $data = $args{source};
        $dict = $args{platform};

    }
    # our internal phrasebook
    else {
        # find and prune down dictionary list
        # NOTE: nested func's from List::* have bad scope, hence using inner grep
        my $family = first { grep { $_ eq $args{platform} } @{$_} } @{__PACKAGE__->__families};
        $dict = [ after_incl { $_ eq $args{platform} } @{$family} ];

        croak "unknown platform: $args{platform}, could not find dictionary"
            if scalar @{$dict} == 0 or ! defined $dict->[0];

        # find our phrasebook file on the filesystem
        (my $pkg_path = __PACKAGE__) =~ s{::}{/}g;
        my (undef, $directory, undef) = fileparse(
            $INC{ $pkg_path .'.pm' }
        );
        croak "couldn't find the NAS Phrasebook home directory"
            if !defined $directory;

        $data = $directory . 'Phrasebook/nas-pb.yml';
        croak "NAS Phrasebook file at $data does not seem to exist"
            if ! -e $data;
    }

    my $self = Data::Phrasebook->new(
        class  => 'Plain',
        loader => 'YAML',
        file   => $data,
        dict   => $dict,
    );
    $self->delimiters(qr{^!}); # it objects to colons
    $self->data('0 but true'); # force load on Phrasebook (a bug in D::P)

    return $self;
}

*{Symbol::qualify_to_ref('load')} = \&new;

1;

# ABSTRACT: Network appliance command-line phrasebook


__END__