File Coverage

blib/lib/Nephia/Setup/Plugin/Relax.pm

Criterion	Covered	Total	%
statement	37	79	46.8
branch	0	2	0.0
condition			n/a
subroutine	9	20	45.0
pod	2	13	15.3
total	48	114	42.1

package Nephia::Setup::Plugin::Relax;
use 5.008005;
use strict;
use warnings;
use parent 'Nephia::Setup::Plugin';
use Data::Section::Simple 'get_data_section';
use File::Spec;
use File::Basename 'dirname';

our $VERSION = "0.02";

sub bundle {
    qw/Assets::Bootstrap Assets::JQuery/;
}

sub fix_setup {
    my $self  = shift;

    my $chain = $self->setup->action_chain;
    $chain->{chain} = [];
    $chain->append('CreateApproot'     => $self->can('create_approot'));
    $chain->append('CreatePSGI'        => $self->can('create_psgi'));
    $chain->append('CreateConfig'      => $self->can('create_config'));
    $chain->append('CreateAppClass'    => $self->can('create_app_class'));
    $chain->append('CreateSomeClasses' => $self->can('create_some_classes'));
    $chain->append('CreateDBDir'       => $self->can('create_db_dir'));
    $chain->append('CreateTemplates'   => $self->can('create_templates'));
    $chain->append('CreateSQL'         => $self->can('create_sql'));
    $chain->append('CreateSetup'       => $self->can('create_setup'));
    $chain->append('CreateCPANFile'    => $self->can('create_cpanfile'));

    push @{$self->setup->deps->{requires}}, (
        'Plack::Middleware::Static'           => '0',
        'Plack::Middleware::Session'          => '0',
        'Plack::Middleware::CSRFBlock'        => '0',
        'Cache::Memcached::Fast'              => '0',
        'DBI'                                 => '0',
        'DBD::SQLite'                         => '0',
        'Data::Page::Navigation'              => '0',
        'Otogiri'                             => '0',
        'Nephia::Plugin::Dispatch'            => '0.03',
        'Nephia::Plugin::FillInForm'          => '0',
        'Nephia::Plugin::JSON'                => '0.03',
        'Nephia::Plugin::ResponseHandler'     => '0',
        'Nephia::Plugin::View::Xslate'        => '0',
        'Nephia::Plugin::ErrorPage'           => '0',
        'Nephia::Plugin::FormValidator::Lite' => '0',
        'Nephia'                              => '0.87',
    );
}

sub load_data {
    my ($class, $setup, @path) = @_;
    my $str = get_data_section(@path);
    $setup->process_template($str);
}

sub create_approot {
    my ($setup, $context) = @_;
    $setup->stop(sprintf('%s is Already exists', $setup->approot)) if -d $setup->approot;
    $setup->makepath('.');
}

sub create_psgi {
    my ($setup, $context) = @_;
    my $data = __PACKAGE__->load_data($setup, 'app.psgi');
    $setup->spew('app.psgi', $data);
}

sub create_config {
    my ($setup, $context) = @_;

    my $common = __PACKAGE__->load_data($setup, 'common.pl');
    $setup->spew('config', 'common.pl', $common);

    $setup->{dbfile} = File::Spec->catfile('var', 'db.sqlite3');
    my $data = __PACKAGE__->load_data($setup, 'config.pl');
    for my $env (qw/local dev real/) {
        $setup->spew('config', "$env.pl", $data);
    }
}

sub create_db_dir {
    my ($setup, $context) = @_;
    $setup->makepath('var');
}

sub create_app_class {
    my ($setup, $context) = @_;
    my $data = __PACKAGE__->load_data($setup, 'MyClass.pm');
    $setup->spew($setup->classfile, $data);
}

sub create_some_classes {
    my ($setup, $context) = @_;
    for my $subclass ( qw/C::Root C::API::Member M M::DB M::DB::Member M::Cache/ ) {
        $setup->{tmpclass} = join('::', $setup->appname, $subclass);
        my $data = __PACKAGE__->load_data($setup, $subclass);
        $setup->spew('lib', split('::', $setup->{tmpclass}.'.pm'), $data);
    }
}

sub create_templates {
    my ($setup, $context) = @_;
    for my $template ( qw/index include::layout include::navbar error/ ) {
        my $file = File::Spec->catfile( split('::', $template) ). '.tt';
        my $data = __PACKAGE__->load_data($setup, $file);
        $setup->makepath('view', dirname($file));
        $setup->spew('view', $file, $data);
    }
}

sub create_sql {
    my ($setup, $context) = @_;
    for my $type ( qw/ mysql sqlite / ) {
        my $data = __PACKAGE__->load_data($setup, $type.'.sql');
        $setup->spew('sql', $type.'.sql', $data);
    }
}

sub create_setup {
    my ($setup, $context) = @_;
    my $data = __PACKAGE__->load_data($setup, 'setup.sh');
    $setup->spew('script', 'setup.sh', $data);
    chmod 0755, File::Spec->catfile($setup->approot, qw/script setup.sh/);
}

sub create_cpanfile {
    my ($setup, $context) = @_;
    $setup->spew('cpanfile', $setup->cpanfile);
}

1;
__DATA__