File Coverage

blib/lib/Nagios/Passive/CommandFile.pm

Criterion	Covered	Total	%
statement	14	30	46.6
branch	0	12	0.0
condition			n/a
subroutine	5	7	71.4
pod			n/a
total	19	49	38.7

package Nagios::Passive::CommandFile;

use strict;
use Carp;
use Moo;
use MooX::late;

extends 'Nagios::Passive::Base';

has 'command_file'=>(
  is => 'ro',
  isa => 'Str',
  predicate=>'has_command_file'
);

sub BUILD {
  my $self = shift;
  my $cf = $self->command_file;
  croak("$cf is not a named pipe") unless (-p $cf);
};

sub to_string {
  my $s = shift;
  my $output;
  if(defined $s->service_description) {
    $output = sprintf "[%d] PROCESS_SERVICE_CHECK_RESULT;%s;%s;%d;%s %s - %s\n",
      $s->time, $s->host_name, $s->service_description, $s->return_code,
      $s->check_name, $s->_status_code, $s->_quoted_output;
  } else {
    $output = sprintf "[%d] PROCESS_HOST_CHECK_RESULT;%s;%d;%s %s - %s\n",
      $s->time, $s->host_name, $s->return_code,
      $s->check_name, $s->_status_code, $s->_quoted_output;
  }
  return $output;
}

sub submit {
  my $s = shift;
  croak("no external_command_file given") unless $s->has_command_file;
  my $cf = $s->command_file;
  my $output = $s->to_string;

  # I hope this is the correct way to deal with named pipes
  local $SIG{PIPE} = 'IGNORE';
  open(my $f, ">>", $cf) or croak("cannot open $cf: $!");
  print $f $output       or croak("cannot write to pipe: $!");
  close($f)              or croak("cannot close $cf");
  return length($output);
}

1;
__END__