File Coverage

blib/lib/MySQL/DateFormat.pm

Criterion	Covered	Total	%
statement	7	9	77.7
branch			n/a
condition			n/a
subroutine	3	3	100.0
pod			n/a
total	10	12	83.3

package MySQL::DateFormat;

use strict;
use Carp;
use Date::Calc;

use vars qw($VERSION $VERSION_DATE);

$VERSION = "1.01";
$VERSION_DATE = "January 9, 2002";

sub new {
    my $proto = shift;
    my $class = ref($proto) || $proto;
    my $self = {};
	%{ $self->{args} } = @_;
	unless ($self->{args}->{format}) {
		croak "[$$] No format specified. Value of 'format' arg must be 'us' or 'eu'.";
	}
    bless($self, $class);
    return $self;
}

sub toMySQL {
	my $self = shift;
	my $date = shift;

	unless ($date) {
		carp "[$$] No date supplied";
		return 0;
	}

	$date =~ s#/#-#g; # we accept either

	my ($d, $m, $y);
	my ($a, $b, $c) = split("-", $date);

	unless ($a and $b and $c) {
		carp "[$$] Invalid date [$a/$b/$c]";
		return 0;
	}

	if ($self->{args}->{format} eq 'eu') {
		# Europe format: DD/MM/YYYY
		$d = $a; $m = $b; $y = $c;
	} elsif ($self->{args}->{format} eq 'us') {
		# USA format: MM/DD/YYYY
		$m = $a; $d = $b; $y = $c;
	} else {
		carp "[$$] Invalid format specified. Value of 'format' arg must be 'us' or 'eu'.";
		return 0;
	}

    if ($self->{args}->{century_cutoff} and $self->{args}->{century_cutoff} eq 'disallow'
        and $y !~ m/^\d{4}$/) {
        carp "[$$] Two-digit year supplied when four digits required";
        return 0;
    }

	$m = sprintf("%0.2d", $m);
	$d = sprintf("%0.2d", $d);

	my $cutoff = 20;
	if ($self->{args}->{century_cutoff} and $self->{args}->{century_cutoff} =~ m/^\d{1,2}$/) {
		$cutoff = $self->{args}->{century_cutoff};
	}
	$y = ($y < 100) ? ($y > $cutoff) ? $y + 1900 : $y + 2000 : $y;

	unless (Date::Calc::check_date($y,$m,$d)) {
		carp "[$$] Invalid date [y:$y m:$m d:$d]";
		return 0;
	}

	return join("-", $y, $m, $d);
}

sub frMySQL {
	my $self = shift;
	my $date = shift;

	unless ($date) {
		carp "[$$] No date supplied";
		return 0;
	}

	$date =~ s#/#-#g;
	my ($y,$m,$d) = split("-", $date);

	unless (Date::Calc::check_date($y,$m,$d)) {
       	carp "[$$] Invalid date [y:$y m:$m d:$d]";
       	return 0;
   	}

	if ($self->{args}->{informal}) {
		$m =~ s/^0//;
		$d =~ s/^0//;
	}

	my $separator = '/';
	if ($self->{args}->{separator}) {
		$separator = $self->{args}->{separator};
	}

	my @elements = ($m,$d,$y);
	@elements = ($d,$m,$y) if $self->{args}->{format} and $self->{args}->{format} eq 'eu';

	return join($separator, @elements);
}

1;

__END__