File Coverage

blib/lib/Music/PitchNum/German.pm

Criterion	Covered	Total	%
statement	36	36	100.0
branch	16	18	88.8
condition			n/a
subroutine	7	7	100.0
pod	2	2	100.0
total	61	63	96.8

# -*- Perl -*-
#
# For BACH.
#
# Run perldoc(1) on this file for additional documentation.

package Music::PitchNum::German;

use 5.010000;
use Moo::Role;
use POSIX qw/floor/;
use Scalar::Util qw/looks_like_number/;

our $VERSION = '0.06';

# for pitchnum (TODO make these attributes or otherwise f(x) calls?)
my %NOTE2NUM = (
  C => 0,
  D => 2,
  E => 4,
  F => 5,
  G => 7,
  A => 9,
  B => 10,
  H => 11,
);
# NOTE lilypond picky about "ees" and "aes" in deutsch mode
my %NUM2NOTE = (
  0  => 'c',
  1  => 'des',
  2  => 'd',
  3  => 'es',
  4  => 'e',
  5  => 'f',
  6  => 'ges',
  7  => 'g',
  8  => 'as',
  9  => 'a',
  10 => 'b',
  11 => 'h',
);

##############################################################################
#
# METHODS

sub pitchname {
  my ( $self, $number ) = @_;
  die "need a number for pitchname\n" if !looks_like_number $number;

  my $octave = floor( $number / 12 ) - 1;
  my $note   = $NUM2NOTE{ $number % 12 };

  $note .= (q{'}) x ( $octave - 3 ) if $octave > 3;
  $note .= (q{,}) x ( 3 - $octave ) if $octave < 3;

  return $note;
}

sub pitchnum {
  my ( $self, $name ) = @_;

  # already a pitch number, but nix the decimal foo
  return int $name if looks_like_number $name;

  my $pitchnum;

  # octave indication only follows accidental, accidental only after note
  if ( $name =~
    m/ (? [A-Ha-h] ) (? es(?:es)? | is(?:is)? )? (? [,]{1,10}|[']{1,10} )? /x
    ) {
    my $octave = $+{octave};
    my $chrome = $+{chrome};
    my $note   = $+{note};

    $pitchnum = $NOTE2NUM{ uc $note } + 12 * 4;

    if ( defined $octave ) {
      $pitchnum += 12 * length($octave) * ( $octave =~ m/[,]/ ? -1 : 1 );
    }

    if ( defined $chrome ) {
      $chrome =~ tr/s//d;
      $pitchnum += length($chrome) * ( $chrome =~ m/e/ ? -1 : 1 );
    }
  }

  return $pitchnum;
}

1;
__END__