File Coverage

blib/lib/MooX/LazyRequire.pm

Criterion	Covered	Total	%
statement	25	27	92.5
branch	6	8	75.0
condition	2	6	33.3
subroutine	6	6	100.0
pod			n/a
total	39	47	82.9

package MooX::LazyRequire;
use strictures 1;

our $VERSION = '0.001001';
$VERSION = eval $VERSION;

use Carp;
use Sub::Quote;
use Class::Method::Modifiers qw(install_modifier);

sub import {
  my ($class) = @_;
  my $target = caller;

  install_modifier $target, 'around', 'has', sub {
    my $orig = shift;
    my ($attrs, %opts) = @_;
    my @attrs = ref $attrs ? @$attrs : $attrs;
    if ($opts{lazy_required}) {
      if (exists $opts{lazy} && !$opts{lazy}) {
        croak "LazyRequire can't be used with lazy => 0";
      }
      elsif (exists $opts{default} || exists $opts{builder}) {
        croak "You may not use both a builder or a default and lazy_required for one attribute ("
          . (join ', ', @attrs) . ")";
      }
      $opts{lazy} = 1;
      for my $attr (@attrs) {
        my $opts = {
          default => quote_sub(qq{
            Carp::croak("Attribute '\Q$attr\E' must be provided before calling reader");
          }),
          %opts,
        };
        $orig->($attr, %$opts);
      }
    }
    else {
      $orig->($attrs, %opts);
    }
  }
}

1;

__END__