File Coverage

blib/lib/MooX/Aliases.pm

Criterion	Covered	Total	%
statement	65	65	100.0
branch	16	18	88.8
condition	2	3	66.6
subroutine	10	10	100.0
pod			n/a
total	93	96	96.8

package MooX::Aliases;
use strictures 1;

our $VERSION = '0.001004';
$VERSION = eval $VERSION;

use Carp;
use Class::Method::Modifiers qw(install_modifier);

sub import {
  my ($class) = @_;
  my $target = caller;

  my $around = do { no strict 'refs'; \&{"${target}::around"} }
    or croak "$target is not a Moo class or role";

  my $make_alias = sub {
    my ($from, $to) = @_;
    if (!$target->can($to)) {
      croak "Cannot find method $to to alias";
    }

    no strict 'refs';
    *{"${target}::${from}"} = sub {
      goto &{$_[0]->can($to)};
    };
  };

  {
    no strict 'refs';
    *{"${target}::alias"} = $make_alias;
  }

  my $installed_buildargs;
  my %init_args;
  install_modifier $target, 'around', 'has', sub {
    my $orig = shift;
    my ($attr, %opts) = @_;
    $attr =~ s/^\+//;

    my $aliases = delete $opts{alias};
    return $orig->($attr, %opts)
      unless $aliases;

    $aliases = [ $aliases ]
      if !ref $aliases;

    my $name = defined $opts{init_arg} ? $opts{init_arg} : $attr;
    my @names = @$aliases;
    if (!exists $opts{init_arg} || defined $opts{init_arg}) {
      unshift @names, $name;
    }
    $init_args{$name} = \@names;

    my $out = $orig->($attr, %opts);

    for my $alias (@$aliases) {
      $make_alias->($alias => $attr);
    }

    if (!$installed_buildargs) {
      $installed_buildargs = 1;
      $around->('BUILDARGS', sub {
        my $orig = shift;
        my $self = shift;
        my $args = $self->$orig(@_);
        for my $attr (keys %init_args) {
          my @init = grep { exists $args->{$_} } (@{$init_args{$attr}});
          if (@init > 1) {
            croak "Conflicting init_args: (" . join(', ', @init) . ")";
          }
          elsif (@init == 1) {
            $args->{$attr} = delete $args->{$init[0]};
          }
        }
        return $args;
      });
    }

    return $out;
  };
}

1;

__END__