File Coverage

lib/Mojolicious/Plugin/ReverseProxy.pm

Criterion	Covered	Total	%
statement	27	39	69.2
branch	2	10	20.0
condition	2	5	40.0
subroutine	6	7	85.7
pod	1	1	100.0
total	38	62	61.2

package Mojolicious::Plugin::ReverseProxy;
use Mojo::Base 'Mojolicious::Plugin';
use Mojo::Transaction::HTTP;
use Mojo::UserAgent;
use Mojo::URL;
use Carp qw(croak);

# let's have our own private unadulterated useragent
# instead of using the shared one from app. Who knows
# what all the others are doing to the poor thing.

my $ua = Mojo::UserAgent->new(cookie_jar => Mojo::UserAgent::CookieJar->new(ignore => sub { 1 }));

our $VERSION = '0.705';

my $make_req = sub {
    my $c = shift;
    my $dest_url = Mojo::URL->new(shift);
    my $mount_point = shift;
    my $tx = Mojo::Transaction::HTTP->new( req=> $c->req->clone );
    my $url = $tx->req->url;
    $url->scheme($dest_url->scheme);
    $url->host($dest_url->host);
    $url->port($dest_url->port);
    if ($mount_point){
        my $req_path = $url->path;
        $req_path =~ s[^\Q${mount_point}\E/*][];
        $url->path($req_path);
    }
    $tx->req->headers->header('Host',$url->host_port);
    return $tx;
};

sub register {
    my $self = shift;
    my $app = shift;
    my $conf = shift;
    if ($conf->{helper_name}){
        die "helper_name is no more. In Mojolicious::Plugin::ReverseProxy 0.6 the API changed radically. Please check the docs.";
    }
    my $dest_url = $conf->{destination_url} or die "the destination_url parameter is mandatory";
    my $req_processor = $conf->{req_processor};
    my $res_processor = $conf->{res_processor};
    my $routes = $conf->{routes} || $app->routes;
    my $mount_point = $conf->{mount_point} || '';
    $mount_point =~ s{/$}{};
    my $log = $app->log;

    $routes->any($mount_point.'/*catchall' => { catchall => '' })->to(cb => sub {
        my $c = shift;
        $c->render_later;
        my $tx = $c->$make_req($dest_url,$mount_point);
        $req_processor->($c,$tx->req) if ref $req_processor eq 'CODE';
        # if we call $c->rendered in the preprocessor,
        # we are done ...
        return if $c->stash('mojo.finished');
        $ua->start($tx, sub {
             my ($ua,$tx) = @_;
             my $res = $tx->res;
             $res_processor->($c,$res) if ref $res_processor eq 'CODE';
             $c->tx->res($res);
             $c->rendered;
        });
    });
}

1;

__END__