File Coverage

blib/lib/Mojolicious/Plugin/MountPSGI.pm

Criterion	Covered	Total	%
statement	24	33	72.7
branch	8	18	44.4
condition	0	3	0.0
subroutine	3	3	100.0
pod	1	1	100.0
total	36	58	62.0

package Mojolicious::Plugin::MountPSGI;
use Mojo::Base 'Mojolicious::Plugin';
use Mojolicious::Plugin::MountPSGI::Proxy;


our $VERSION = '0.15';

sub register {
  my ($self, $app, $conf) = @_;

  my $rewrite = delete $conf->{rewrite};

  # Extract host and path
  my $prefix = (keys %$conf)[0];
  my ($host, $path);
  if ($prefix =~ /^(\*\.)?([^\/]+)(\/.*)?$/) {
    $host = quotemeta $2;
    $host = "(?:.*\\.)?$host" if $1;
    $path = $3;
    $path = '/' unless defined $path;
    $host = qr/^$host$/i;
  }
  else { $path = $prefix }

  my %args = (
    rewrite => $rewrite ? $path : undef,
  );

  unless ($ENV{PLACK_ENV}) {
    $args{mode} = $app->mode;
  }

  my $psgi = $conf->{$prefix};
  if (ref $psgi) {
    $args{app} = $psgi;
  } else {
    unless (-r $psgi) {
      my $abs = $app->home->rel_file($psgi);
      $psgi = $abs if -r $abs;
    }
    $args{script} = $psgi;
  }

  my $proxy = Mojolicious::Plugin::MountPSGI::Proxy->new(%args);

  # Generate route
  my $route = $app->routes->any($path)->partial(1)->to(app => $proxy);
  if ($host) {
    my $requires = $route->can('requires') || $route->can('over');
    $route->$requires(host => $host);
  }

  return $route;
}


1;
__END__