File Coverage

blib/lib/Mojolicious/Plugin/Humane.pm

Criterion	Covered	Total	%
statement	68	69	98.5
branch	15	20	75.0
condition	6	6	100.0
subroutine	13	13	100.0
pod	3	3	100.0
total	105	111	94.5

package Mojolicious::Plugin::Humane;
use Mojo::Base 'Mojolicious::Plugin';

use File::Spec;
use File::Basename ();
use File::ShareDir ();

our $VERSION = '0.07';
$VERSION = eval $VERSION;

has 'humane_version' => '3.2.0';

has 'static_path' => sub {
  my $self = shift;
  $self->path('humane-' . $self->humane_version);
};

has 'template' => 'humane_template';

has 'theme' => 'libnotify';

sub path {
  my $self   = shift;
  my $folder = shift;

  my $local = File::Spec->catdir( File::Basename::dirname(__FILE__), 'Humane', 'files', $folder );
  return $local if -d $local;

  my $share = File::Spec->catdir( File::ShareDir::dist_dir('Mojolicious-Plugin-Humane'), $folder );
  return $share if -d $share;

  die "Cannot find files. Tried '$local' and '$share'.\n";
}

sub register {
  my ($plugin, $app) = (shift, shift);
  my %conf = ref $_[0] ? %{ shift() } : @_;

  $conf{auto} //= 1;      #/# highlight fix

  # Append static to directories
  push @{$app->static->paths}, $plugin->static_path;
  push @{$app->renderer->classes}, __PACKAGE__;

  $app->helper( humane => sub { $plugin } );

  $app->helper( humane_stash => sub {
    my $self  = shift;
    my $key   = 'humane.stash';
    my $stash = $self->stash($key) || [];

    if ( @_ ) {
      push @$stash, @_;
      $self->stash( $key => $stash );
    }

    return $stash;
  });

  $app->helper( humane_flash => sub {
    my $self  = shift;
    my $key   = 'humane.flash';
    my $flash = $self->flash($key) || [];

    if ( @_ ) {
      push @$flash, @_;
      $self->flash( $key => $flash );
    }

    return $flash;
  });

  $app->helper( humane_include => sub {
    my $self = shift;
    $self->include( #TODO use render_to_string once Mojo 5.00 is required
      template => $self->humane->template,
    );
  });

  $app->helper( humane_messages => sub {
    my $self = shift;
    my @messages = (
      @{ $self->humane_flash },
      @{ $self->humane_stash },
    );
    return @messages;
  });

  $app->hook( after_dispatch => sub {
    my $c = shift;
    my @messages = $c->humane_messages;
    return unless @messages;

    my $dom  = $c->res->dom;
    my $head = $dom->at('head') or return;

    my $append = $c->humane_include;
    $head->append_content( $append );
    $c->tx->res->body( $dom->to_string );
  } ) if $conf{auto};

  return $plugin;
}

sub all_themes {
  my $self = shift;
  my $path = $self->static_path;
  opendir my $dh, $path or die "Cannot open $path\n";
  return map { s/\.css$// ? $_ : () } readdir $dh;
}

1;

__DATA__