File Coverage

blib/lib/MojoX/CustomTemplateFileParser/Plugin/To/Pod.pm

Criterion	Covered	Total	%
statement	41	41	100.0
branch	4	8	50.0
condition	2	5	40.0
subroutine	5	5	100.0
pod	1	1	100.0
total	53	60	88.3

package MojoX::CustomTemplateFileParser::Plugin::To::Pod;

use strict;
use warnings;
use 5.10.1;
our $VERSION = '0.10';

use Moose::Role;

sub to_pod {
    my $self = shift;
    my $test_index = shift;
    my $want_all_examples = shift || 0;

    my $tests_at_index = $self->test_index->{ $test_index };
    my @out = ();

    TEST:
    foreach my $test (@{ $tests_at_index }) {
        next TEST if $want_all_examples && !$test->{'is_example'};

        if(scalar @{ $test->{'lines_before'} }) {
            push @out => "\n", '=begin html', "\n",
                      '<p>', @{ $test->{'lines_before'} }, '</p>',
                      "\n", '=end html',
                      "\n";
        }

        push @out => @{ $test->{'lines_template'} }, "\n";
        if(scalar @{ $test->{'lines_between'} }) {
            push @out => '=begin html', "\n",
                      '<p>',@{ $test->{'lines_between'} }, '</p>',
                      "\n", '=end html',
                      "\n";
        }
        push @out => @{ $test->{'lines_expected' } }, "\n";
        if(scalar @{ $test->{'lines_after'} }) {
            push @out => '=begin html', "\n",
                      '<p>',@{ $test->{'lines_after'} }, '</p>',
                      "\n", '=end html', "\n";
        }
    }

    my $out = join "\n" => @out;
    $out =~ s{\n\n\n+}{\n\n}g;
    $out =~ s{\n+=begin html\n+}{\n\n=begin html\n\n}g;
    $out =~ s{\n+=end html\n+}{\n\n=end html\n\n}g;

    return $out;

}

1;


=encoding utf-8

=head1 NAME

MojoX::CustomTemplateFileParser::Plugin::To::Pod - Create pod

=head1 SYNOPSIS

  use MojoX::CustomTemplateFileParser;

  my $parser = MojoX::CustomTemplateFileParser->new(path => '/path/to/file.mojo', output => ['Pod']);

  print $parser->to_pod;

=head1 DESCRIPTION

MojoX::CustomTemplateFileParser::Plugin::To::Pod is an output plugin to L<MojoX::CustomTemplateFileParser>.

=head2 to_pod()

This method is added to L<MojoX::CustomTemplateFileParser> objects created with C<output =E<gt> ['Pod']>.

=head1 SEE ALSO

=over 4

=item * L<Dist::Zilla::Plugin::InsertExample::FromMojoTemplates>

=item * L<MojoX::CustomTemplateFileParser::Plugin::To::Pod>

=item * L<MojoX::CustomTemplateFileParser::Plugin::To::Test>

=back

=head1 AUTHOR

Erik Carlsson E<lt>[e-mail]<gt>

=head1 COPYRIGHT

Copyright 2014- Erik Carlsson

=head1 LICENSE

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself.

=cut