File Coverage

blib/lib/Mojolicious/Plugin/FeedReader.pm

Criterion	Covered	Total	%
statement	64	64	100.0
branch	17	22	77.2
condition	20	21	95.2
subroutine	13	13	100.0
pod	3	4	75.0
total	117	124	94.3

package Mojolicious::Plugin::FeedReader;
use Mojo::Base 'Mojolicious::Plugin';

use Mojo::Feed::Reader;

our $VERSION = "0.20";

use Scalar::Util qw(blessed);

has feed_reader => sub { Mojo::Feed::Reader->new };

sub new {
  my $self = shift;
  return $self->SUPER::new(feed_reader => Mojo::Feed::Reader->new(@_));
}

sub register {
  my ($self, $app) = @_;
  $self->feed_reader->ua($app->ua);
  $app->helper(parse_feed => sub { shift; $self->parse_rss(@_); });
  $app->helper(parse_rss  => sub { shift; $self->parse_rss(@_); });
  $app->helper(find_feeds => sub { shift; $self->find_feeds(@_); });
  $app->helper(parse_opml => sub { shift; $self->feed_reader->parse_opml(@_) });
}

sub parse_rss {
  my $self = shift;
  my @args = @_;

  # handle deprecated case of using Mojo::DOM as input
  if (ref $args[0] && blessed $args[0] && $args[0]->isa('Mojo::DOM')) {
    $args[0] = $args[0]->to_string();
  }

  # handle special case of being passed a callback - make non-blocking call
  if ( ref $args[0]
    && blessed $args[0]
    && $args[0]->isa('Mojo::URL')
    && ref $args[1]
    && ref $args[1] eq 'CODE')
  {
    $self->feed_reader->ua->get(
      $args[0],
      sub {
        my $tx = pop;
        my $feed = undef;
        my $result = $tx->result;
        if ($result->is_success) {
          my $feed_obj = $self->feed_reader->parse($result->body,
            $result->content->charset);
          if ($feed_obj) {
            $feed = $feed_obj->to_hash;
            $feed->{'htmlUrl'} = delete $feed->{'link'};
            for (keys %$feed) { delete $feed->{$_} if ($feed->{$_} eq '') };
            delete $feed->{'items'} if (scalar @{$feed->{'items'}} == 0);
          }
        }
        $args[1]->($feed);
      }
    );
  }
  else {
    my $feed_obj = $self->feed_reader->parse(@args);
    return undef unless ($feed_obj);
    my $feed = $feed_obj->to_hash;
    $feed->{'htmlUrl'} = delete $feed->{'link'};
    for (keys %$feed) { delete $feed->{$_} if ($feed->{$_} eq '') };
    delete $feed->{'items'} if (scalar @{$feed->{'items'}} == 0);
    return $feed;
  }
}

sub find_feeds {
  my $self = shift;
  my $cb;
  if (ref $_[-1] && ref $_[-1] eq 'CODE') {
    $cb = pop @_;
  }
  my $promise = $self->feed_reader->discover(@_);
  if ($cb) {
    $promise->then($cb);
  }
  else {
    my @res;
    $promise->then(sub { @res = @_; })->wait;
    return @res;
  }
}

1;

__END__