File Coverage

blib/lib/Mojar/Google/Analytics/Response.pm

Criterion	Covered	Total	%
statement	6	34	17.6
branch	0	14	0.0
condition	0	17	0.0
subroutine	2	4	50.0
pod	2	2	100.0
total	10	71	14.0

package Mojar::Google::Analytics::Response;
use Mojo::Base -base;

our $VERSION = 1.011;

use Mojar::Util 'snakecase';

# Attributes

has [qw(code content error message success)];

has start_index => 1;
has contains_sampled_data => !!0;
has column_headers => sub {[]};
has total_results => 0;
has rows => sub {[]};
has [qw(items_per_page profile_info next_link totals_for_all_results)];

# Public methods

sub parse {
  my ($self, $res) = @_;

  if ($res->is_success) {
    delete @$self{qw(code content error message)};
    my $j = $res->json;
    $self->{snakecase($_)} = $j->{$_} for keys %$j;
    return $self->success(1);
  }
  else {
    # Got a transaction-level error
    $self->success(undef)->code($res->code || 408)
      ->message($res->message // 'Possible timeout')
      ->error(sprintf 'Error (%u): %s', $_[0]->code, $_[0]->message);

    if ($res and my $j = $res->json) {
      # Got JSON body in response
      $self->content($j);
      my $m = ref($j->{error}) ? $j->{error} : {message => $j->{error} // ''};

      # Got message record
      $self->code($m->{code}) if $m->{code};
      # Take note of headline error
      my $msg = ($m->{message} // $j->{message}) ."\n";

      for my $e (@{$m->{errors} // []}) {
        # Take note of next listed error
        $msg .= sprintf "%s at %s\n%s\n",
            $e->{reason}, ($e->{location} // $e->{domain}), $e->{message};
      }
      $self->message($msg);
    }
    return undef;
  }
}

sub columns {
  my $self = shift;
  return undef unless my $rows = $self->rows;
  return undef unless my $height = @$rows;
  return undef unless my $width = @{$$rows[0]};

  my @cols = map [], 1 .. $width;
  for (my $j = 0; $j < $height; ++$j) {
    for (my $i = 0; $i < $width; ++$i) {
      push @{$cols[$i]}, $$rows[$j][$i]
    }
  }
  return \@cols;
}
# See https://gist.github.com/niczero/cc792d919ff7c32cbccf04fa821a1cb0 for bm

1;
__END__