File Coverage

blib/lib/Module/Build/Prereqs/FromCPANfile.pm

Criterion	Covered	Total	%
statement	44	44	100.0
branch	9	10	90.0
condition			n/a
subroutine	10	10	100.0
pod	1	1	100.0
total	64	65	98.4

package Module::Build::Prereqs::FromCPANfile;
use strict;
use warnings;
use Module::CPANfile 1.0000;
use CPAN::Meta::Prereqs 2.132830;
use Exporter qw(import);
use version 0.80;

our $VERSION = "0.02";

our @EXPORT = our @EXPORT_OK = qw(mb_prereqs_from_cpanfile);

sub mb_prereqs_from_cpanfile {
    my (%args) = @_;
    my $version = $args{version};
    $version = _get_mb_version() if not defined $version;
    my $cpanfile_path = $args{cpanfile};
    $cpanfile_path = "cpanfile" if not defined $cpanfile_path;

    my $file = Module::CPANfile->load($cpanfile_path);
    return _prereqs_to_mb($file->prereqs, $version);
}

sub _get_mb_version {
    require Module::Build;
    return $Module::Build::VERSION;
}

sub _prereqs_to_mb {
    my ($prereqs, $mb_version_str) = @_;
    my %result = ();
    my $mb_version = version->parse($mb_version_str);
    _put_result($prereqs->requirements_for("runtime", "requires"), \%result, "requires");
    _put_result($prereqs->requirements_for("runtime", "recommends"), \%result, "recommends");
    _put_result($prereqs->requirements_for("runtime", "conflicts"), \%result, "conflicts");
    if($mb_version < version->parse("0.30")) {
        _put_result($prereqs->merged_requirements(["configure", "build", "test"], ["requires"]),
                    \%result, "build_requires");
    }elsif($mb_version < version->parse("0.4004")) {
        _put_result($prereqs->merged_requirements(["build", "test"], ["requires"]),
                    \%result, "build_requires");
        _put_result($prereqs->requirements_for("configure", "requires"), \%result, "configure_requires");
    }else {
        foreach my $phase (qw(configure build test)) {
            _put_result($prereqs->requirements_for($phase, "requires"), \%result, "${phase}_requires");
        }
    }
    return %result;
}

sub _put_result {
    my ($requirements, $result_hashref, $result_key) = @_;
    my $reqs_hashref = $requirements->as_string_hash;
    if(keys %$reqs_hashref) {
        $result_hashref->{$result_key} = $reqs_hashref;
    }
}


1;
__END__