File Coverage

blib/lib/Mindcal.pm

Criterion	Covered	Total	%
statement	51	53	96.2
branch	6	12	50.0
condition	2	6	33.3
subroutine	14	14	100.0
pod	0	8	0.0
total	73	93	78.4

package Mindcal;
use strict;
use warnings;
use DateTime;
use Log::Log4perl qw(:easy);

our $VERSION = '0.01';

###########################################
sub new {
###########################################
    my($class, %options) = @_;

    my $self = {
        month_items => [qw(0 3 3 6 1 4 6 2 5 0 3 5)],
        century_adjust => {
            qw(1700 4 1800 2 1900 0 2000 6
               2100 4 2200 2 2300 0)
        },
        dows => [qw[Sunday Monday Tuesday Wednesday Thursday Friday Saturday]],
        %options,
    };

    if(!defined $self->{date} or
        ref($self->{date}) ne "DateTime") {
        LOGDIE "new() called without DateTime date";
    }

    bless $self, $class;
    return $self;
}

###########################################
sub month_item {
###########################################
    my($self) = @_;

    return $self->{month_items}->[$self->{date}->month() - 1];
}

###########################################
sub year_item {
###########################################
    my($self) = @_;

    use integer;
    my $year  = $self->{date}->year();
    my $year2 = ($year % 100);

    return (($year2 + ($year2 / 4)) % 7);
}

###########################################
sub century_adjust {
###########################################
    my($self) = @_;

    use integer;

    my $year  = $self->{date}->year();
    my $month = $self->{date}->month();
    my $cent = $year / 100;

    if(!exists $self->{century_adjust}->{ $cent * 100 }) {
        LOGDIE "Century $cent not supported (yet).";
    }

    return $self->{century_adjust}->{ $cent*100 };
}

###########################################
sub day_item {
###########################################
    my($self) = @_;

    return $self->{date}->day();
}

###########################################
sub weekday {
###########################################
    my($self) = @_;

    my $dow = $self->year_item() +
              $self->month_item() +
              $self->day_item() +
              $self->adjust;

    return $self->{dows}->[ $dow % 7 ];
}

###########################################
sub adjust {
###########################################
    my($self) = @_;

    my $adj = $self->century_adjust();
    my $month = $self->{date}->month();

    $adj-- if $self->is_leap_year() and $month <= 2;

    return $adj;
}

###########################################
sub is_leap_year {
###########################################
    my($self) = @_;

    my $year = $self->{date}->year();

    return 0 if $year % 4;
    return 1 if $year % 100;
    return 0 if $year % 400;
    return 1;
}

1;
__END__