File Coverage

blib/lib/MetaCPAN/Client/Release.pm

Criterion	Covered	Total	%
statement	16	30	53.3
branch	0	4	0.0
condition			n/a
subroutine	6	9	66.6
pod	3	3	100.0
total	25	46	54.3

use strict;
use warnings;
package MetaCPAN::Client::Release;
# ABSTRACT: A Release data object
$MetaCPAN::Client::Release::VERSION = '2.029000';
use Moo;
use Ref::Util qw< is_hashref >;
use JSON::MaybeXS qw< decode_json >;

with 'MetaCPAN::Client::Role::Entity',
     'MetaCPAN::Client::Role::HasUA';

my %known_fields = (
    scalar => [qw<
        abstract
        archive
        author
        authorized
        checksum_md5
        checksum_sha256
        date
        deprecated
        distribution
        download_url
        first
        id
        maturity
        main_module
        name
        status
        version
        version_numified
    >],

    arrayref => [qw<
        dependency
        license
        provides
    >],

    hashref => [qw<
        metadata
        resources
        stat
        tests
    >],
);

my @known_fields =
    map { @{ $known_fields{$_} } } qw< scalar arrayref hashref >;

foreach my $field (@known_fields) {
    has $field => (
        is      => 'ro',
        lazy    => 1,
        default => sub {
            my $self = shift;
            return $self->data->{$field};
        },
    );
}

sub _known_fields { return \%known_fields }

sub changes {
    my $self = shift;
    my $url  = sprintf "https://fastapi.metacpan.org/changes/%s/%s", $self->author, $self->name;
    my $res = $self->ua->get($url);
    return unless is_hashref($res);
    my $content = decode_json $res->{'content'};
    return $content->{'content'};
}

sub metacpan_url {
    my $self = shift;
    sprintf( "https://metacpan.org/release/%s/%s", $self->author, $self->name )
}

sub contributors {
    my $self = shift;
    my $url = sprintf( "https://fastapi.metacpan.org/release/contributors/%s/%s", $self->author, $self->name );
    my $res = $self->ua->get($url);
    return unless is_hashref($res);
    my $content = decode_json $res->{'content'};
    return $content->{'contributors'};
}

1;

__END__