File Coverage

blib/lib/MediaWiki/CleanupHTML.pm

Criterion	Covered	Total	%
statement	68	76	89.4
branch	11	14	78.5
condition	3	6	50.0
subroutine	14	14	100.0
pod	3	3	100.0
total	99	113	87.6

package MediaWiki::CleanupHTML;
$MediaWiki::CleanupHTML::VERSION = '0.0.6';
use 5.008;

use strict;
use warnings;

use HTML::TreeBuilder::XPath ();
use Scalar::Util             (qw(blessed));



sub new
{
    my $class = shift;

    my $self = bless {}, $class;

    $self->_init(@_);

    return $self;
}

sub _is_processed
{
    my $self = shift;

    if (@_)
    {
        $self->{_is_processed} = shift;
    }

    return $self->{_is_processed};
}

sub _fh
{
    my $self = shift;

    if (@_)
    {
        $self->{_fh} = shift;
    }

    return $self->{_fh};
}

sub _tree
{
    my $self = shift;

    if (@_)
    {
        $self->{_tree} = shift;
    }

    return $self->{_tree};
}

sub _init
{
    my ( $self, $args ) = @_;

    if ( !exists( $args->{'fh'} ) )
    {
        Carp::confess(
            "MediaWiki::CleanupHTML->new was not passed a filehandle.");
    }

    $self->_fh( $args->{fh} );

    my $tree = HTML::TreeBuilder::XPath->new;

    $self->_tree($tree);

    $self->_tree->parse_file( $self->_fh );

    $self->_is_processed(0);

    return;
}

sub _process
{
    my $self = shift;

    if ( $self->_is_processed() )
    {
        return;
    }

    my $tree = $self->_tree;

    {
        my @nodes = $tree->findnodes('//div[@class="editsection"]');

        foreach my $n (@nodes)
        {
            $n->detach();
            $n->delete();
        }
    }

    {
        my @nodes = map { $tree->findnodes( '//h' . $_ ) } ( 2 .. 4 );

        foreach my $h2 (@nodes)
        {
            my $a_tag = $h2->left();
            if (   blessed($a_tag)
                && $a_tag->tag() eq "a"
                && $a_tag->attr('name') )
            {
                my $id = $a_tag->attr('name');
                $h2->attr( 'id', $id );
                $a_tag->detach();
                $a_tag->delete();
            }
        }
    }

    my (@divs_to_delete) = (
        $tree->findnodes('//div[@class="printfooter"]'),
        $tree->findnodes('//div[@id="catlinks"]'),
        $tree->findnodes('//div[@class="visualClear"]'),
        $tree->findnodes('//div[@id="column-one"]'),
        $tree->findnodes('//div[@id="footer"]'),
        $tree->findnodes('//head//style'),
        $tree->findnodes('//script'),
    );

    foreach my $div (@divs_to_delete)
    {
        $div->detach();
        $div->delete();
    }

    $self->_is_processed(1);

    return;
}


sub print_into_fh
{
    my ( $self, $fh ) = @_;

    $self->_process();

    print {$fh} $self->_tree->as_XML();
}


sub destroy_resources
{
    my $self = shift;

    if ( defined( $self->_tree() ) )
    {
        $self->_tree->delete();
        $self->_tree( undef() );
    }

    return;
}

sub DESTROY
{
    my $self = shift;

    $self->destroy_resources();

    return;
}


1;    # End of MediaWiki::CleanupHTML

__END__