File Coverage

blib/lib/Math/SMA.pm

Criterion	Covered	Total	%
statement	45	45	100.0
branch	9	10	90.0
condition	2	2	100.0
subroutine	6	6	100.0
pod	1	2	50.0
total	63	65	96.9

package Math::SMA;
use Scalar::Util qw(looks_like_number);
use Moo;
use namespace::autoclean;

our $VERSION = '0.01';
$VERSION = eval $VERSION;

has size => (
	is =>'ro',
	isa => sub { die "$_[0] is not an integer!" unless(looks_like_number($_[0]) && $_[0] >= 1)},
	required => '1',
);

has last_avg => (
	is =>'ro',
	isa => sub { die "$_[0] is not a number!" unless looks_like_number $_[0]},
	writer => '_set_last_avg',
);

has precision => (
	is => 'rw',
	isa => sub { die "$_[0] is not a number!" unless looks_like_number $_[0]},
	default => 2,
);

has values => (
	is => 'ro',
	isa => sub { die "$_[0] is not an array ref!" unless ref($_[0]) eq 'ARRAY'},
	default => sub { [] },
);


sub BUILD
{
	my $self = shift();
	my $values = $self->values();
	my $size = $self->size();

	return unless defined $values;

	#perfectly valid to pass in values to constructor
	#however, not valid to have more values than size()
	if(@{$values} > $size){
		@{$values} = splice(@{$values}, -1 * $size);
	}

	$self->_set_last_avg($self->_raw_average());

}

sub sma
{
	my ($self, $current) = @_;
	my $last = $self->last_avg();
	my $values = $self->values();
	my $size = $self->size();
	my $prec = $self->precision();
	my $obsolete;
	my $avg;

	return sprintf("%.${prec}f",$last) unless defined $current;
	die "sma() works on numbers only!" unless looks_like_number $current;

	push(@{$values}, $current);

	#return simple avg if not enough periods
	if(@{$values} <= $size){
		$self->_set_last_avg($self->_raw_average());
		return sprintf("%.${prec}f", $self->last_avg());
	}

	$obsolete = shift(@{$values});

	$avg = $last - ($obsolete/$size) + ($current/$size);
	$self->_set_last_avg($avg);

	return sprintf("%.${prec}f", $avg);
}


sub _raw_average
{
	my $self = shift();
	my $size = @{$self->values()} || 1;
	my $total = 0;
	foreach (@{$self->values}){
		$total += $_;
	}
	return $total / $size;
}



1;

__END__