File Coverage

blib/lib/Math/NumSeq/KlarnerRado.pm

Criterion	Covered	Total	%
statement	48	51	94.1
branch	16	18	88.8
condition	9	12	75.0
subroutine	12	12	100.0
pod	3	3	100.0
total	88	96	91.6

# Copyright 2011, 2012, 2013, 2014 Kevin Ryde

# This file is part of Math-NumSeq.
#
# Math-NumSeq is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by the
# Free Software Foundation; either version 3, or (at your option) any later
# version.
#
# Math-NumSeq is distributed in the hope that it will be useful, but
# WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
# or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
# for more details.
#
# You should have received a copy of the GNU General Public License along
# with Math-NumSeq.  If not, see .


# http://infolab.stanford.edu/TR/CS-TR-72-269.html
# http://infolab.stanford.edu/TR/CS-TR-72-275.html

package Math::NumSeq::KlarnerRado;
use 5.004;
use strict;
use List::Util;

use vars '$VERSION', '@ISA';
$VERSION = 72;

use Math::NumSeq;
use Math::NumSeq::Base::IteratePred;
@ISA = ('Math::NumSeq::Base::IteratePred', 'Math::NumSeq');

# uncomment this to run the ### lines
#use Devel::Comments;

# use constant name => Math::NumSeq::__('Klarner-Rado');
use constant description => Math::NumSeq::__('Klarner-Rado sequence 1,2,4,5,8,9,etc being 1 and then if n in the sequence so are 2n, 3n+2 and 6n+3.');
use constant i_start => 1;

sub values_min {
  my ($self) = @_;
  return $self->{'start'};
}

use constant parameter_info_array =>
  [ { name    => 'start',
      type    => 'integer',
      default => 1,
      minimum => 1,
      width   => 3,
    },
  ];

# cf A005659   2n-2, 3n-3, starting 4
#    A005660   2n+2, 3n+3, starting 3
#    A005661   2n-2, 3n-3, starting 5
#    A005662   2n+2, 3n+3
#    A185661   2n+1, 3n+1, starting 1
#    A005658   2n+1, 3n+1, 6n+1, starting 1
#
my @oeis_anum;
$oeis_anum[1] = 'A005658';
sub oeis_anum {
  my ($self) = @_;
  return $oeis_anum[$self->{'start'}];
}

# sub rewind {
#   my ($self) = @_;
#   $self->{'i'} = $self->i_start;
#
#   # $self->{'pending'} = { 1 => undef };
#   # $self->{'pref_ref'} = \'';
#   # $self->{'pstart'} = 0;
# }

# sub next {
#   my ($self) = @_;
#   ### KlarnerRado next(): "$self->{'i'}"
#
#   # my $pstart = $self->{'pstart'};
#   # vec($$pref,
#   # # my $pending = $self->{'pending'};
#   # return ($self->{'i'}++, $min);
#
#   my $pending = $self->{'pending'};
#   my $min = List::Util::min (keys %$pending);
#   delete $pending->{$min};
#   @{$pending}{2*$min,3*$min+2,6*$min+3} = ();
#   return ($self->{'i'}++, $min);
# }

sub pred {
  my ($self, $value) = @_;
  ### KlarnerRado pred(): $value

  my $start = $self->{'start'};
  my @pending = ($value);
  for (;;) {
    ### @pending
    ### $value

    if ($value <= $start) {
      if ($value == $start) {
        return 1;
      }
      $value = pop @pending || return 0;

    } elsif ($value == 2 || $value == 4) {
      $value /= 2; # from 2k
    } elsif ($value == 5) {
      $value = 1; # from 3k+2

    } elsif ($value >= 6) {
      #         mod6
      # 2k   = 0,2, 4
      # 3k+2 =   2,   5
      # 6k+3 =     3
      #
      my $mod = ($value % 6);
      if ($mod == 0 || $mod == 4) {
        # 6k under 2n -> 3k is 0,3 mod 6
        # 6k+4 under 2n -> 3k+2 is 2,5 mod 6
        $value /= 2;

      } elsif ($mod == 2) {
        ### 6k+2 ...
        #  under 2n -> 3k+2 is 2,5 mod 6
        #  under 3n+2 -> 2k is 0,2,4 mod 6
        push @pending, ($value-2)/3;   # n <- 3n+2
        $value /= 2;                   # n <- 2n

      } elsif ($mod == 3) {
        # 6k+3 -> k
        $value -= 3;
        $value /= 6;

      } elsif ($mod == 5) {
        # 6k+5 under 3n+2 -> 2*k+1
        $value -= 2;
        $value /= 3;

      } else {
        # mod == 1
        $value = pop @pending || return 0;
      }
    } else {
      $value = pop @pending || return 0;
    }
  }
}

1;
__END__