File Coverage

lib/Math/MatrixDecomposition/Util.pm

Criterion	Covered	Total	%
statement	45	48	93.7
branch	12	14	85.7
condition			n/a
subroutine	13	13	100.0
pod	6	6	100.0
total	76	81	93.8

## Math/MatrixDecomposition/Util.pm --- utility functions.

# Copyright (C) 2010 Ralph Schleicher.  All rights reserved.

# This program is free software; you can redistribute it and/or
# modify it under the same terms as Perl itself.

## Code:

package Math::MatrixDecomposition::Util;

use strict;
use warnings;
use Exporter qw(import);
use POSIX qw(fmod);

BEGIN
{
  our $VERSION = '1.06';
  our @EXPORT_OK = qw(eps isnan mod min max sign hypot cdiv);
  our %EXPORT_TAGS = (all => [@EXPORT_OK]);
}

# Machine precision.
my $epsilon = 1.0;

*eps = sub () { $epsilon; };

INIT
{
  my $tem;

  while (1)
    {
      $tem = 1.0 + $epsilon / 2.0;
      last if $tem == 1.0;
      $epsilon /= 2.0;
    }
}

# Not-a-number.
sub isnan ($)
{
  my $x = shift;

  $x != $x;
}

# Remainder of floating-point division.
*mod = \&fmod;

# Minimum value.
sub min ($$)
{
  my ($a, $b) = @_;

  $a < $b ? $a : $b;
}

# Maximum value.
sub max ($$)
{
  my ($a, $b) = @_;

  $a > $b ? $a : $b;
}

# Transfer sign.
sub sign ($$)
{
  my ($a, $b) = @_;

  ($a < 0) == ($b < 0) ? $a : -$a;
}

# Length of the hypotenuse of a right triangle.
sub hypot ($$)
{
  my $a = abs (shift);
  my $b = abs (shift);

  # Work variables.
  my ($s, $t);

  if ($a >= $b)
    {
      $s = $a;
      # Avoid division by zero.
      $t = ($a == $b ? 1.0 : $b / $a);
    }
  else
    {
      $s = $b;
      $t = $a / $b;
    }

  $s * sqrt (1.0 + $t * $t);
}

# Complex division.
sub cdiv ($$$$)
{
  my ($a_re, $a_im, $b_re, $b_im) = @_;

  # Work variables.
  my ($r, $d, @z);

  if (abs ($b_re) > abs ($b_im))
    {
      $r = $b_im / $b_re;
      $d = $b_re + $r * $b_im;
      @z = (($a_re + $r * $a_im) / $d,
	    ($a_im - $r * $a_re) / $d);
    }
  else
    {
      $r = $b_re / $b_im;
      $d = $b_im + $r * $b_re;
      @z = (($r * $a_re + $a_im) / $d,
	    ($r * $a_im - $a_re) / $d);
    }

  @z;
}

1;

__END__