File Coverage

blib/lib/Math/Matlab/Remote.pm

Criterion	Covered	Total	%
statement	28	53	52.8
branch	4	12	33.3
condition	0	2	0.0
subroutine	10	15	66.6
pod	6	6	100.0
total	48	88	54.5

package Math::Matlab::Remote;

use strict;
use vars qw($VERSION $URI $TIMEOUT $USER $PASS);

BEGIN {
	$VERSION = sprintf "%d.%03d", q$Revision: 1.6 $ =~ /: (\d+)\.(\d+)/;
}

use Math::Matlab;
use base qw( Math::Matlab );

use HTTP::Request;
use HTTP::Response;
use LWP::UserAgent;
use URI::URL;

##-----  assign defaults, unless already set externally  -----
$URI		= ''	unless defined $URI;
$TIMEOUT	= 300	unless defined $TIMEOUT;	## default = 5 min
$USER		= ''	unless defined $USER;
$PASS		= ''	unless defined $PASS;

##-----  Public Class Methods  -----
sub new {
	my ($class, $href) = @_;
	my $self	= {
		uri		=> defined($href->{uri})		? $href->{uri}		: $URI,
		timeout	=> defined($href->{timeout})	? $href->{timeout}	: $TIMEOUT,
		user	=> defined($href->{user})		? $href->{user}		: $USER,
		pass	=> defined($href->{pass})		? $href->{pass}		: $PASS,
		err_msg	=> '',
		result	=> ''
	};

	bless $self, $class;
}

##-----  Public Object Methods  -----
sub execute {
	my ($self, $code, $rel_mwd) = @_;

	## set up the request
	my %form = (
		'RAW_OUTPUT'	=> 1,
		'CODE'			=> $code,
		'REL_MWD'		=> $rel_mwd || ''
	);
	my $request = new HTTP::Request('POST' => $self->uri);
	$request->content_type('application/x-www-form-urlencoded');
	my $curl = new URI::URL('http:');
	$curl->query_form( %form );
	$request->content($curl->equery);
 	$request->authorization_basic($self->user, $self->pass)	if $self->user;

	## set up the user agent
	my $ua = new LWP::UserAgent;
	$ua->agent( __PACKAGE__ . "/$VERSION " . $ua->agent);
	$ua->timeout($self->timeout);

	## do the request
	my $response = $ua->request($request);

	if ($response->is_error) {
		$self->err_msg( $response->status_line );
		return 0;
	} else {
		$self->{'result'} = $response->content;
		return 1;
	}
}

sub uri {		my $self = shift; return $self->_getset('uri',		@_); }
sub timeout {	my $self = shift; return $self->_getset('timeout',	@_); }
sub user {		my $self = shift; return $self->_getset('user',		@_); }
sub pass {		my $self = shift; return $self->_getset('pass',		@_); }

1;
__END__