File Coverage

blib/lib/Mail/Exim/MainLogParser.pm

Criterion	Covered	Total	%
statement	82	90	91.1
branch	39	48	81.2
condition	20	40	50.0
subroutine	12	14	85.7
pod	5	5	100.0
total	158	197	80.2

package Mail::Exim::MainLogParser;
use strict;
use warnings;

BEGIN {
    use Exporter ();
    use vars qw($VERSION @ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
    $VERSION     = '0.02';
    @ISA         = qw(Exporter);
    @EXPORT      = qw();
    @EXPORT_OK   = qw(&EximMainLoglineParse EximMainLoglineCompose);
    %EXPORT_TAGS = ();
}

BEGIN {
  use vars      qw(%EXIM_FLAGS %EXIM_FIELD_IDENFIERS);

  # As of 2017-06-08
  # Source: http://www.exim.org/exim-html-current/doc/html/spec_html/ch-log_files.html
  %EXIM_FLAGS = (
	'<='	=>	'message arrival',
	'(='	=>	'message fakereject',
	'=>'	=>	'normal message delivery',
	'->'	=>	'additional address in same delivery',
	'>>'	=>	'cutthrough message delivery',
	'*>'	=>	'delivery suppressed by -N',
	'**'	=>	'delivery failed; address bounced',
	'=='	=>	'delivery deferred; temporary problem',
  );
  %EXIM_FIELD_IDENFIERS = (
	A	=>	'authenticator name (and optional id and sender)',
	C	=>	('SMTP confirmation on delivery'.			'; '.
			'command list for "no mail in SMTP session”'),
	CV	=>	'certificate verification status',
	D	=>	'duration of "no mail in SMTP session”',
	DN	=>	'distinguished name from peer certificate',
	DS	=>	'DNSSEC secured lookups',
	DT	=>	'on => lines: time taken for a delivery',
	F	=>	'sender address (on delivery lines)',
	H	=>	'host name and IP address',
	I	=>	'local interface used',
	K	=>	'CHUNKING extension used',
	id	=>	'message id for incoming message',
	P	=>	('on <= lines: protocol used'. 				'; '.
			'on => and ** lines: return path'),
	PRDR	=>	'PRDR extension used',
	PRX	=>	'on <= and => lines: proxy address',
	Q	=>	'alternate queue name',
	QT	=>	('on => lines: time spent on queue so far'. 		'; '.
			'on "Completed” lines: time spent on queue'),
	R	=>	('on <= lines: reference for local bounce'. 		'; '.
			'on =>  >> ** and == lines: router name'),
	S	=>	'size of message in bytes',
	SNI	=>	'server name indication from TLS client hello',
	ST	=>	'shadow transport name',
	T	=>	('on <= lines: message subject (topic)'. 		'; '.
			'on => ** and == lines: transport name'),
	U	=>	'local user or RFC 1413 identity',
	X	=>	'TLS cipher suite'
    );
}


sub new
{
    my ($class, %parameters) = @_;

    my $self = bless ({}, ref ($class) || $class);

    return $self;
}

sub _exim_log_main__parse($) {
  my $line = shift || return undef;
  if ($line !~ m/^\d{4}\-\d{2}-\d{2}\s\d{2}\:\d{2}\:\d{2}( [\-\+]\d{4})?/o) {
    warn __PACKAGE__,": Exim log line not in expected format.";
    return undef;
  }
  # Split the line by spaces, and examine each element
  my @line = split(/\s/,$line);
  # To pass this simple filter the string must have a minimum of three elements
  #   [  |  |  |  ]
  return undef unless scalar @line >= 3;
  my $l = {
    'date' => shift @line,
    'time' => shift @line
  };
  # detect if a time zone is provided # Exim: log_timezone=true
  # 2003-04-25 11:17:07 +0100 Start queue run: pid=12762
  if ($line[0] =~ /\+\d{4}/) {
    $l->{'timezone'} = shift @line;
  }

  # detect is the Exim process Id is provided # Exim: log_selector = +pid
  # The parser should not be modifying data, only understanding and separating it
  # For this reason: 'pid': "[]" , as given in the log line
  if ($line[0] =~ /\[\d+\]/) {
    $l->{'pid'} = shift @line;
  }

  # Exim ID Format: 1dIyz2-0002mc-5x
  if ($line[0] =~ /[a-zA-Z0-9]{6}\-[a-zA-Z0-9]{6}\-[a-zA-Z0-9]{2}/) {
    $l->{'eximid'} = shift @line;
  } else {
    # $l->{'eximid'} = undef;
  }

  # Exim log line flag
  if ($line[0] =~ /\<\=|\(\=|\=\>|\-\>|\>\>|\*\>|\*\*|\=\=/) {
    $l->{'flag'} = shift @line;
  } else {
    # mail rejected or completed
    # $l->{'flag'} = undef;
  }

  return $l if ! scalar @line >= 1;

  # If the flag is undefined or delivery failure, then detect either the message or the field identifiers
  # 2020-06-07 18:10:24 1ji4Qp-0002jY-UD Completed
  # 2020-06-07 18:12:18 1ji4Sf-0002jl-Vk H=ugso.tenet.odessa.ua (ugso.odessa.ua) [195.138.65.238] F= rejected after DATA: Your message scored 17.4 SpamAssassin point. Report follows:
  if ( ((!exists $l->{'flag'}) || (!defined $l->{'flag'})) || ($l->{'flag'} eq "**") ) {

    if ( ($line[0] !~ /^[A-Zid]{1,4}\=.*/) || (($line[0] =~ /^([A-Zid]{1,4})\=.*/) && (!exists $EXIM_FIELD_IDENFIERS{$1})) ) {
      # If the element does not start with a known field identifier, we assume the whole line is a message
      while (scalar @line >= 1) {
        $l->{'message'} .= (" ") if defined $l->{'message'};
        $l->{'message'} .= shift @line;
      }
    }

  # If the flag is defined and not a delivery failure, then we expect a mail destination (e.g. email, system pipe, system file, etc)
  } else {

    # Exim Address could be email address, pipe, file, and a string combination of several of these elements
    # 2020-06-07 23:44:57 1ji9ea-0003oh-Tt => :blackhole:  R=pipe_to_useraddress
    # 2020-06-07 21:49:23 1ji7qj-0003Ud-Ss => |/usr/bin/listmgr-queue listmgr  R=pipe_to_listmgr T=address_pipe
    # Skip email detection if element is AAAA=somevalue or id=somevalue, a simple field identifier matcher (where A is alpha)
    # For deferred deliveries (i.e. == flag) email could be: some-identified-realperson=realdomain@some-domain
    while (   (scalar @line >= 1)
           && (   ($line[0] !~ /^[A-Zid]{1,4}\=.*/)
               || (($line[0] =~ /^([A-Zid]{1,4})\=.*/) && (!exists $EXIM_FIELD_IDENFIERS{$1}))
              )
          ) {
      # The element is appended to address until matching a known field identifier
      $l->{'address'} .= (" ") if defined $l->{'address'};
      $l->{'address'} .= shift @line;
    }
  }

  return $l if ! scalar @line >= 1;

  # Exim field identifiers and identifier messages
  $l->{'args'} = [];
  while (scalar @line >= 1) {
    # Matching anything that looks like a field identifier, rather than looking each up in the $EXIM_FIELD_IDENFIERS hash
    if ( ($line[0] =~ /^([A-Zid]{1,4})\=(.*)/) && (exists $EXIM_FIELD_IDENFIERS{$1}) ) {
      my $this_arg = $1;
      my $this_val = $2;
      shift @line;
      while ( (scalar @line >= 1) && (($line[0] !~ /^([A-Zid]{1,4})\=(.*)/) || (!exists $EXIM_FIELD_IDENFIERS{$1})) ) {
        $this_val .= (" " . shift @line);
      }
      push(@{$l->{'args'}},{$this_arg => $this_val});
    } else {
      # If the field identifier is not detected, fall back to message
      # This should only happen if the text in the element does not match any field identifiers
      $l->{'message'} = shift @line;
      while ( (scalar @line >= 1) && (($line[0] !~ /^([A-Zid]{1,4})\=(.*)/) || (!exists $EXIM_FIELD_IDENFIERS{$1})) ) {
        $l->{'message'} .= (" " . shift @line);
      }
    }
  }

  if (scalar @line >= 1) {
    warn ("Error Parsing Line: $line\n"."Unparsed log line data: ".join("; ",@line)."\n");
  }

  return $l;
}

sub _exim_log_main__compose ($) {
  my $parsed = shift || return undef;
  return undef unless ref $parsed eq "HASH";
  my @s_args;
  foreach my $arg (@{$parsed->{'args'}}) {
      push(@s_args, map{qq{$_=$arg->{$_}}} keys %$arg)
  }
  my @s_line;
  push(@s_line,$parsed->{'date'})     if exists $parsed->{'date'};
  push(@s_line,$parsed->{'time'})     if exists $parsed->{'time'};
  push(@s_line,$parsed->{'timezone'}) if exists $parsed->{'timezone'};
  push(@s_line,$parsed->{'pid'})      if exists $parsed->{'pid'};
  push(@s_line,$parsed->{'eximid'})   if exists $parsed->{'eximid'};
  push(@s_line,$parsed->{'flag'})     if exists $parsed->{'flag'};
  push(@s_line,$parsed->{'address'})  if exists $parsed->{'address'};
  push(@s_line, join(" ", @s_args)) if @s_args >= 1;
  push(@s_line,$parsed->{'message'})  if exists $parsed->{'message'};
  return(join(" ", @s_line));
}

sub EximMainLoglineParse($) {
  return _exim_log_main__parse($_[0]);
}

sub EximMainLoglineCompose($) {
  return _exim_log_main__compose($_[0]);
}

sub parse($) {
  my $self = shift;
  return _exim_log_main__parse($_[0]);
}

sub compose($) {
  my $self = shift;
  return _exim_log_main__compose($_[0]);
}

1;
__END__