File Coverage

blib/lib/Lyrics/Fetcher/AZLyrics.pm

Criterion	Covered	Total	%
statement	34	54	62.9
branch	3	8	37.5
condition	1	3	33.3
subroutine	7	8	87.5
pod	1	1	100.0
total	46	74	62.1

package Lyrics::Fetcher::AZLyrics;

# $Id$

use 5.008000;
use strict;
use warnings;
use LWP::UserAgent;
use HTML::Strip;
use Carp;

our $VERSION = '0.05';

# the HTTP User-Agent we'll send:
our $AGENT = "Perl/Lyrics::Fetcher::AZLyrics $VERSION";



sub fetch {

    my $self = shift;
    my ( $artist, $song ) = @_;

    # reset the error var, change it if an error occurs.
    $Lyrics::Fetcher::Error = 'OK';

    unless ($artist && $song) {
        carp($Lyrics::Fetcher::Error =
            'fetch() called without artist and song');
        return;
    }

    $artist =~ s/[^a-z0-9]//gi;
    $song   =~ s/[^a-z0-9]//gi;

    my $url = 'http://www.azlyrics.com/lyrics/';
    $url .= join('/', lc $artist, lc $song) . '.html';

    my $ua = new LWP::UserAgent;
    $ua->timeout(6);
    $ua->agent($AGENT);
    my $res = $ua->get($url);
    if ( $res->is_success ) {
        my $lyrics = _parse($res->content);
        return $lyrics;
    } else {

        if ($res->status_line =~ /^404/) {
            $Lyrics::Fetcher::Error =
                'Lyrics not found';
            return;
        } else {
            carp($Lyrics::Fetcher::Error =
                "Failed to retrieve $url (".$res->status_line.')');
            return;
        }
    }


}


sub _parse {
    my $html = shift;
    my $hs = HTML::Strip->new();

    # Nasty - look for everything in between the two ringtones links:
    if (my ($goodbit) = $html =~
        m{<\!-- END OF RINGTONE 1 -->(.+)<\!-- RINGTONE 2 -->}msi)
    {
        my $text = $hs->parse($goodbit);

        # Remove mentions of ringtones:
        $text =~ s/^ .+ ringtone .+ $//xmgi;

        # Scoop out any credits for these lyrics:
        my @credits;
        @Lyrics::Fetcher::azcredits = ();
        while ($text =~ s{\[ Thanks \s to \s (.+) \]}{}xgi) {
            push @Lyrics::Fetcher::azcredits, $1;
        }

        $text =~ s/\s*\[.+at \s www.AZLyrics.com\s+\]\s*//xmgi;

        # finally, clear up excess blank lines:
        $text =~ s/(\r?\n){2,}/\n\n/gs;

        return $text;

    } else {
        carp "Failed to identify lyrics on result page";
        return;
    }

} # end of sub parse



1;
__END__