File Coverage

blib/lib/Lustre/Info/Export.pm

Criterion	Covered	Total	%
statement	6	62	9.6
branch	0	16	0.0
condition	0	6	0.0
subroutine	2	10	20.0
pod	5	8	62.5
total	13	102	12.7

#
# Lustre NID/export Subclass
#
# (C) 2010 Adrian Ulrich -
#
# This program is free software; you can redistribute it and/or
# modify it under the same terms as Perl itself.
#
#
package Lustre::Info::Export;
use strict;
use warnings;


##########################################################################
# Returns a new Export Object
sub new {
	my($classname, %args) = @_;
	my $self = { super=>$args{super}, export=>$args{export}, export_stats=>{}, graph_stats=>[{},{}] };
	bless($self,$classname);
}

##########################################################################
# Return name of this nid
sub get_name {
	my($self) = @_;
	return $self->{export};
}

##########################################################################
# AB(uses) the OST-Module to get statistics for this client
sub collect_export_stats {
	my($self, $ostlist) = @_;

	$ostlist = $self->{super}->get_ost_list if !$ostlist;

	foreach my $ost (@$ostlist) {
		$self->{export_stats}->{$ost} ||= $self->{super}->get_ost($ost);        # Creates a new ost-object if empty
		$self->{export_stats}->{$ost}->collect_client_stats([$self->get_name]); # collect stats for this-client only
	}

	return undef;
}

##########################################################################
# Return per-ost statistics of this NID/EXPORT
sub get_export_stats {
	my($self) = @_;

	my $es = $self->{export_stats};
	my $r  = {};
	foreach my $ost_name (keys(%$es)) {
		my $ost_ref = $es->{$ost_name};
		my $stats   = $ost_ref->get_client_stats;
		$r->{$ost_name} = $stats->{$self->get_name};
	}
	return $r;
}

##########################################################################
# Undocumented alias for get_export_stats
sub get_client_stats {
	my($self) = @_;
	return $self->get_export_stats;
}

##########################################################################
# undocumented alias for collect_export_stats
sub collect_client_stats {
	my($self) = @_;
	return $self->collect_export_stats;
}

sub collect_brw_stats {
	my($self, $ostlist) = @_;

	$ostlist = $self->{super}->get_ost_list if !$ostlist;

	my $own_name = $self->get_name;
	my $tstamp   = 0;
	my $junk     = {};
	foreach my $ost (@$ostlist) {
		my $pfs_file = "/proc/fs/lustre/obdfilter/$ost/exports/$own_name/brw_stats";
		next unless -f $pfs_file;
		my $ref = $self->{super}->_parse_brw_file($pfs_file);
		$tstamp ||= $ref->{timestamp};
		$junk = $self->{super}->sum_up_deep(2, $ref->{data}, $junk);
	}

	$junk->{timestamp} = $tstamp; # Add first timestamp to ref (as expected by get_*_stats)

	my $stats_ref = $self->{graph_stats};
	shift(@$stats_ref);
	push(@$stats_ref, $junk);
	return $junk;
}

sub get_brw_stats {
	my($self) = @_;

	my $r1   = $self->{graph_stats}->[0];
	my $r2   = $self->{graph_stats}->[1];
	my $ts1  = $r1->{timestamp} or return undef;
	my $ts2  = $r2->{timestamp} or return undef;
	my $junk = {};

	foreach my $label (keys(%$r1)) {
		my $rx = $r1->{$label};
		next if ref($rx) ne 'HASH';
		next if !exists($r2->{$label});

		foreach my $line (keys(%$rx)) {
			next if !exists($r2->{$label}->{$line});
			foreach my $action (keys(%{$rx->{$line}})) {
				my $value = $r2->{$label}->{$line}->{$action} - $r1->{$label}->{$line}->{$action};
				$junk->{$label}->{$line}->{$action} = $value;
			}
		}
	}
	return({_slice=>($ts2-$ts1), data=>$junk});
}


1;
__END__