File Coverage

blib/lib/Log/ger/Plugin/WithDie.pm

Criterion	Covered	Total	%
statement	30	30	100.0
branch	6	8	75.0
condition	6	6	100.0
subroutine	8	8	100.0
pod	0	1	0.0
total	50	53	94.3

package Log::ger::Plugin::WithDie;

our $DATE = '2017-08-04'; # DATE
our $VERSION = '0.002'; # VERSION

use strict;
use warnings;

use Log::ger ();

sub get_hooks {
    my %conf = @_;

    return {
        create_routine_names => [
            __PACKAGE__, 50,
            sub {
                my %args = @_;

                my $levels = \%Log::ger::Levels;

                return [{
                    log_subs    => [
                        (map { ["log_${_}_die", $_, "default"] }
                             grep {$levels->{$_} > 0 && $levels->{$_} <= 20} keys %$levels),
                    ],
                    is_subs     => [],
                    log_methods => [
                        (map { ["${_}_die", $_, "default"] }
                             grep {$levels->{$_} > 0 && $levels->{$_} <= 20} keys %$levels),
                    ],
                    logml_methods => [
                    ],
                    is_methods  => [
                    ],
                }, 0];
            }],
        before_install_routines => [
            __PACKAGE__, 50,
            sub {
                my %args = @_;

                # wrap the logger
                for my $r (@{ $args{routines} }) {
                    my ($code, $name, $numlevel, $type) = @$r;
                    if ($type eq 'log_sub' && $name =~ /\Alog_\w+_die\z/) {
                        $r->[0] = sub {
                            $code->(@_);
                            die $args{formatters}{default}(@_)."\n";
                        };
                    } elsif ($type eq 'log_method' && $name =~ /\A\w+_die\z/) {
                        $r->[0] = sub {
                            $code->(@_);
                            shift;
                            die $args{formatters}{default}(@_)."\n";
                        };
                    }
                }
            },
        ],
    };
}

1;
# ABSTRACT: Add *_die logging routines

__END__