File Coverage

blib/lib/Log/ger/Plugin/Multisets.pm

Criterion	Covered	Total	%
statement	28	28	100.0
branch	2	4	50.0
condition	1	9	11.1
subroutine	6	6	100.0
pod	0	2	0.0
total	37	49	75.5

package Log::ger::Plugin::Multisets;

use strict;
use warnings;

use Log::ger ();

our $AUTHORITY = 'cpan:PERLANCAR'; # AUTHORITY
our $DATE = '2022-05-16'; # DATE
our $DIST = 'Log-ger-Plugin-Multisets'; # DIST
our $VERSION = '0.005'; # VERSION

sub meta { +{
    v => 2,
} }

sub get_hooks {
    my %plugin_conf = @_;

    die "Please specify at least one of ".
        "logger_sub_prefixes|level_checker_sub_prefixes|logger_method_prefixes|level_checker_method_prefixes"
        unless
        $plugin_conf{logger_sub_prefixes} ||
        $plugin_conf{level_checker_sub_prefixes} ||
        $plugin_conf{logger_method_prefixes} ||
        $plugin_conf{level_checker_method_prefixes};

    return {
        create_routine_names => [
            __PACKAGE__, # key
            50,          # priority
            sub {        # hook
                my %hook_args = @_; # see Log::ger::Manual::Internals/"Arguments passed to hook"

                my $levels = [keys %Log::ger::Levels];

                my $routine_names = {};
                for my $key0 (qw(logger_sub level_checker_sub logger_method level_checker_method)) {
                    my $routine_names_key = "${key0}s";
                    my $plugin_conf_key = "${key0}_prefixes";
                    $routine_names->{$routine_names_key} = [];
                    next unless $plugin_conf{$plugin_conf_key};
                    for my $prefix (keys %{ $plugin_conf{$plugin_conf_key} }) {
                        my $init_args = $plugin_conf{$plugin_conf_key}{$prefix};
                        push @{ $routine_names->{$routine_names_key} }, map
                            { ["${prefix}$_", $_, undef, $init_args] }
                            @$levels;
                    }
                }

                [$routine_names, 1];
            }],
    };
}

1;
# ABSTRACT: Create multiple sets of logger routines, each set with its own init arguments

__END__