File Coverage

blib/lib/Log/Minimal/Object.pm

Criterion	Covered	Total	%
statement	40	41	97.5
branch	1	2	50.0
condition	15	17	88.2
subroutine	18	18	100.0
pod	1	12	8.3
total	75	90	83.3

package Log::Minimal::Object;
use 5.008005;
use strict;
use warnings;
use Log::Minimal ();

our $VERSION = "0.02";

use constant {
    ORIGINAL_PRINT => $Log::Minimal::PRINT,
    ORIGINAL_DIE   => $Log::Minimal::DIE,
    DEFAULT_TRACE_LEVEL => 2,
};

sub new {
    my $class = shift;

    my %args = scalar @_ == 1 ? %{$_[0]} : @_;

    bless {
        color             => $args{color} || 0,
        die               => $args{die} || ORIGINAL_DIE,
        print             => $args{print} || ORIGINAL_PRINT,
        autodump          => $args{autodump} || 0,
        trace_level       => $args{trace_level} || DEFAULT_TRACE_LEVEL,
        log_level         => $args{log_level} || 'DEBUG',
        escape_whitespace => $args{escape_whitespace} || 0,
    }, $class;
}

sub critf   { shift->_log('critf',   @_) }
sub warnf   { shift->_log('warnf',   @_) }
sub infof   { shift->_log('infof',   @_) }
sub debugf  { shift->_log('debugf',  @_) }
sub critff  { shift->_log('critff',  @_) }
sub warnff  { shift->_log('warnff',  @_) }
sub infoff  { shift->_log('infoff',  @_) }
sub debugff { shift->_log('debugff', @_) }
sub croakf  { shift->_log('croakf',  @_) }
sub croakff { shift->_log('croakff', @_) }
sub ddf     { shift->_log('ddf',     @_) }

sub _log {
    my $self = shift;
    my $meth = shift;

    local $Log::Minimal::COLOR             = $self->{color};
    local $Log::Minimal::AUTODUMP          = $self->{autodump};
    local $Log::Minimal::TRACE_LEVEL       = $self->{trace_level};
    local $Log::Minimal::LOG_LEVEL         = $self->{log_level};
    local $Log::Minimal::DIE               = $self->{die};
    local $Log::Minimal::PRINT             = $self->{print};
    local $Log::Minimal::ESCAPE_WHITESPACE = $self->{escape_whitespace};

    $self->{$meth} ||= Log::Minimal->can($meth);
    $self->{$meth}->(@_);
}

1;
__END__