File Coverage

blib/lib/Log/Dispatch/Pipe.pm

Criterion	Covered	Total	%
statement	40	40	100.0
branch	8	8	100.0
condition	6	9	66.6
subroutine	11	11	100.0
pod	1	2	50.0
total	66	70	94.2

package Log::Dispatch::Pipe;
use 5.008001;
use strict;
use warnings;
our $VERSION = "0.04";

use Log::Dispatch 2.00;
use parent 'Log::Dispatch::Output';

use Scalar::Util qw(openhandle);

sub new {
    my ($proto, %params) = @_;
    my $class = ref $proto || $proto;

    my $self = bless {}, $class;
    $self->_basic_init(%params);
    $self->_init(%params);

    $self;
}

sub _init {
    my ($self, %params) = @_;

    $self->{output_to} = $params{output_to};
    $self->{binmode}   = $params{binmode};

    $self->_open_handle if $params{try_at_init};
}

sub _open_handle {
    my $self = shift;

    open my $fh, '|-', $self->{output_to}
        or die "Failed opening pipe: $!";

    my $oldfh = select $fh;
    $| = 1;
    select $oldfh;

    binmode $fh, $self->{binmode}
        if $self->{binmode};

    $fh;
}

sub log_message {
    my ($self, %params) = @_;

    $self->{fh} ||= $self->_open_handle;

    my $fh = $self->{fh};
    print $fh $params{message};
}

sub DESTROY {
    my $self = shift;
    close $self->{fh} if $self->{fh} and openhandle($self->{fh});
}

1;
__END__