File Coverage

blib/lib/Log/Any/Plugin/ANSIColor.pm

Criterion	Covered	Total	%
statement	38	38	100.0
branch	13	14	92.8
condition	5	6	83.3
subroutine	8	8	100.0
pod	0	1	0.0
total	64	67	95.5

package Log::Any::Plugin::ANSIColor;
use 5.008001;
use strict;
use warnings;

our $VERSION = "0.02";

use Log::Any::Plugin::Util  qw( get_old_method set_new_method );
use Log::Any::Adapter::Util qw(
    log_level_aliases logging_aliases logging_methods
);
use Term::ANSIColor         qw( colored colorvalid );

our %default = (
    emergency  => 'bold magenta',
    alert      => 'magenta',
    critical   => 'bold red',
    error      => 'red',
    warning    => 'yellow',
    debug      => 'cyan',
    trace      => 'blue',
);

sub install {
    my ($class, $adapter_class, %color_map) = @_;

    if ((delete $color_map{default}) || (keys %color_map == 0)) {
        # Copy the default colors, leaving any the user has specified.
        for my $method (keys %default) {
            $color_map{$method} ||= $default{$method};
        }
    }

    my %aliases = log_level_aliases();
    for my $alias (keys %aliases) {
        my $method = $aliases{$alias};

        $color_map{$alias} = $color_map{$method}
            if exists $color_map{$method};
    }

    for my $method_name ( logging_methods(), logging_aliases() ) {
        if (my $color = delete $color_map{$method_name}) {
            # Specifying none as the color name disables colorisation for that
            # method.
            next if $color eq 'none';

            if (!colorvalid($color)) {
                warn "Invalid color name \"$color\" for $method_name";
                next;
            }

            my $old_method = get_old_method($adapter_class, $method_name);
            set_new_method($adapter_class, $method_name, sub {
                my $self = shift;
                $self->$old_method(
                    # Colorise non-ref arguments, leave ref args alone.
                    map { ref $_ ? $_ : colored([$color], $_) } @_
                );
            });
        }
    }

    if (my @remainder = sort keys %color_map) {
        warn 'Unknown logging methods: ', join(', ', @remainder);
    }
}

1;
__END__