File Coverage

blib/lib/Log/Any/Adapter/MojoLog.pm

Criterion	Covered	Total	%
statement	21	21	100.0
branch	2	2	100.0
condition	1	3	33.3
subroutine	8	8	100.0
pod	0	1	0.0
total	32	35	91.4

package Log::Any::Adapter::MojoLog;

use strict;
use warnings;

our $VERSION = '0.03';
$VERSION = eval $VERSION;

use Log::Any::Adapter::Util qw(make_method);
use base qw(Log::Any::Adapter::Base);

use Mojo::Log;

sub init {
    my ($self) = @_;
    $self->{logger} ||= Mojo::Log->new;
}

# Create logging methods
#
foreach my $method ( Log::Any->logging_methods ) {
    my $mojo_method = $method;

    # Map log levels down to Mojo::Log levels where necessary
    #
    for ($mojo_method) {
        s/trace/debug/;
        s/notice/info/;
        s/warning/warn/;
        s/critical|alert|emergency/fatal/;
    }

    make_method(
        $method,
        sub {
            my $self = shift;
            return $self->{logger}->$mojo_method(@_);
        }
    );
}

# Create detection methods: is_debug, is_info, etc.
#

my $true = sub { 1 };
foreach my $method ( Log::Any->detection_methods ) {
    my $mojo_method = $method;

    # Map log levels down to Mojo::Log levels where necessary
    #
    for ($mojo_method) {
        s/trace/debug/;
        s/notice/info/;
        s/warning/warn/;
        s/critical|alert|emergency/fatal/;
    }

    my $level;
    if ($mojo_method eq 'is_fatal') {
      # is_fatal has been removed since 6.0, it was always true
      $mojo_method = $true;
    } elsif (eval { require Mojolicious; Mojolicious->VERSION('6.47'); 1 }) {
      # as of 6.47 the is_* methods have been removed in favor of
      # is_level($level)
      ($level = $mojo_method) =~ s/^is_//;
      $mojo_method = 'is_level';
    }

    make_method(
        $method,
        sub {
            my $self = shift;
            return $self->{logger}->$mojo_method($level ? $level : ());
        }
    );
}

1;

__END__