File Coverage

blib/lib/Locale/Utils/PlaceholderBabelFish.pm

Criterion	Covered	Total	%
statement	73	73	100.0
branch	28	34	82.3
condition	1	3	33.3
subroutine	15	15	100.0
pod	2	2	100.0
total	119	127	93.7

package Locale::Utils::PlaceholderBabelFish; ## no critic (TidyCode)

use strict;
use warnings;
use Carp qw(confess);
use HTML::Entities qw(encode_entities);
use List::Util qw(min);
use Moo;
use MooX::StrictConstructor;
use MooX::Types::MooseLike::Base qw(Bool CodeRef);
use Scalar::Util qw(looks_like_number);
use namespace::autoclean;

our $VERSION = '0.006';

has is_strict => (
    is  => 'rw',
    isa => Bool,
);

sub default_modifier_code {
    return sub {
        my ( $value, $attributes ) = @_;

        if ( $attributes =~ m{ \b html \b }xms ) {
            $value = encode_entities( $value, q{<>&"} );
        }

        return $value;
    }
};

has modifier_code => (
    is      => 'rw',
    isa     => CodeRef,
    clearer => 'clear_modifier_code',
    lazy    => 1,
    default => \&default_modifier_code,
);

has plural_code => (
    is      => 'rw',
    isa     => CodeRef,
    lazy    => 1,
    default => sub {
        return sub {
            my $n = shift;
            0 + (
                $n != 1 # en
            );
        };
    },
    clearer => 'clear_plural_code',
);

sub _mangle_value {
    my ($self, $placeholder, $value, $attribute) = @_;

    defined $value
        or return $self->is_strict ? $placeholder : q{};
    defined $attribute
        or return $value;
    $self->modifier_code
        or return $value;
    $value = $self->modifier_code->($value, $attribute);
    defined $value
        or confess 'modifier_code returns nothing or undef';

    return $value;
}

sub expand_babel_fish {
    my ($self, $text, @args) = @_;

    defined $text
        or return $text;
    my $arg_ref = @args == 1
        ? ( ref $args[0] eq 'HASH' ? $args[0] : { count => $args[0] } )
        : {
            @args % 2
            ? confess 'Arguments expected pairwise'
            : @args
        };

    # placeholders
    my $regex = join q{|}, map { quotemeta } keys %{$arg_ref};
    ## no critic (EscapedMetacharacters)
    $text =~ s{
        ( \\ [#] )                     # escaped
        |
        (
            [#] \{
            ( $regex )                 # placeholder
            (?: [ ]* [:] ( [^\}]+ ) )? # attribute
            \}
        )
    }
    {
        $1
        ? $1
        : $self->_mangle_value($2, $arg_ref->{$3}, $4)
    }xmsge;
    ## use critic (EscapedMetacharacters)

    # plural
    my $replace_code = sub {
        my ( $match, $inner, $count ) = @_;

        looks_like_number($count)
            or return $match;
        $inner =~ s{ \\ [|] }{\0}xmsg;
        my @special_plurals;
        my @plurals
            = map {
                m{ \A [=] ( \d+ ) \s+ ( .* ) \z }xms
                    ? do {
                        push @special_plurals, [$1, $2];
                        ();
                    }
                    : $_;
            }
            map { ## no critic (ComplexMappings)
                my $item = $_;
                $item =~ s{ \0 }{\\|}xmsg;
                $item;
            }
            split qr{ [|] }xms, $inner;
        for my $plural ( @special_plurals ) {
            if ( defined $plural->[0] && $plural->[0] == $count ) {
                return $plural->[1];
            }
        }
        @plurals
            or return $match;
        my $index = $self->plural_code->($count);
        $index = min( $index, $#plurals );

        return $plurals[$index];
    };
    ## no critic (EscapedMetacharacters)
    $text =~ s{
        ( \\ \( \( )           # $1: escaped
        |
        (                      # $2: match
            \( \(              # open
            ( .*? )            # $3: inner
            \) \)              # close
            (?: [:] ( \w+ ) )? # $4: count variable name
        )
    }
    {
        $1
        ? $1
        : $replace_code->( $2, $3, $4 ? $arg_ref->{$4} : $arg_ref->{count} )
    }xmsge;
    ## use critic (EscapedMetacharacters)

    # unescape
    $text =~ s{ \\ (.) }{$1}xmsg;

    return $text;
}

__PACKAGE__->meta->make_immutable;

1;

__END__