File Coverage

blib/lib/Locale/TextDomain/OO/Util/JoinSplitLexiconKeys.pm

Criterion	Covered	Total	%
statement	45	45	100.0
branch	26	26	100.0
condition	2	3	66.6
subroutine	12	12	100.0
pod	7	7	100.0
total	92	93	98.9

package Locale::TextDomain::OO::Util::JoinSplitLexiconKeys; ## no critic (TidyCode)

use strict;
use warnings;
use Locale::TextDomain::OO::Util::Constants;
use namespace::autoclean;

our $VERSION = '4.001';

sub instance {
    return __PACKAGE__;
}

sub join_lexicon_key {
    my ( undef, $arg_ref ) = @_;

    my $const = Locale::TextDomain::OO::Util::Constants->instance;

    return join $const->lexicon_key_separator,
        (
            ( defined $arg_ref->{language} && length $arg_ref->{language} )
            ? $arg_ref->{language}
            : 'i-default'
        ),
        ( defined $arg_ref->{category} ? $arg_ref->{category} : q{} ),
        ( defined $arg_ref->{domain}   ? $arg_ref->{domain}   : q{} ),
        ( defined $arg_ref->{project}  ? $arg_ref->{project}  : ()  );
}

sub split_lexicon_key {
    my ( undef, $lexicon_key ) = @_;

    defined $lexicon_key
        or return {};
    my $const = Locale::TextDomain::OO::Util::Constants->instance;
    my ( $language, $category, $domain, $project )
        = split $const->lexicon_key_separator, $lexicon_key, 4; ## no critic (Magic Numbers)

    return {(
        language => $language,
        category => $category,
        domain   => $domain,
        ( defined $project ? ( project  => $project ) : () ),
    )};
}

my $length_or_empty_list = sub {
    my $item = shift;

    defined $item or return;
    length $item or return;

    return $item;
};

sub join_message_key {
    my ( undef, $arg_ref, $format ) = @_;

    my $const = Locale::TextDomain::OO::Util::Constants->instance;

    return join $const->msg_key_separator($format),
        (
            join $const->plural_separator($format),
                $length_or_empty_list->( $arg_ref->{msgid} ),
                $length_or_empty_list->( $arg_ref->{msgid_plural} ),
        ),
        $length_or_empty_list->( $arg_ref->{msgctxt} );
}

sub split_message_key {
    my ( undef, $message_key, $format ) = @_;

    defined $message_key
        or return {};
    my $const = Locale::TextDomain::OO::Util::Constants->instance;
    my ( $text, $context )
        = split $const->msg_key_separator($format), $message_key;
    defined $text
        or $text = q{};
    my ( $singular, $plural )
        = split $const->plural_separator($format), $text;
    defined $singular
        or $singular = q{};
    my $list_if_defined = sub { return defined shift() ? @_ : () };

    return {(
        msgid => $singular,
        $list_if_defined->( $context,  msgctxt      => $context ),
        $list_if_defined->( $plural,   msgid_plural => $plural ),
    )};
}

sub join_message {
    my ( $self, $message_key, $message_value_ref, $format ) = @_;

    defined $message_key
        or $message_key = q{};
    ref $message_value_ref eq 'HASH'
        or $message_value_ref = {};

    return {(
        %{$message_value_ref},
        %{ $self->split_message_key($message_key, $format) },
    )};
}

sub split_message {
    my ( $self, $message, $format ) = @_;

    ref $message eq 'HASH'
        or $message = {};

    my $message_key = $self->join_message_key(
        {(
            map {
                $_ => delete $message->{$_};
            }
            qw( msgctxt msgid msgid_plural )
        )},
        $format,
    );

    return $message_key, $message;
}

1;

__END__