File Coverage

blib/lib/Locale/Maketext/Extract/Plugin/Base.pm

Criterion	Covered	Total	%
statement	37	43	86.0
branch	10	12	83.3
condition			n/a
subroutine	9	12	75.0
pod	7	7	100.0
total	63	74	85.1

package Locale::Maketext::Extract::Plugin::Base;
$Locale::Maketext::Extract::Plugin::Base::VERSION = '1.00';
use strict;

use File::Basename qw(fileparse);

# ABSTRACT: Base module for format parser plugins


sub new {
    my $class = shift;
    my $self = bless { entries => [], }, $class;

    $self->_compile_file_types(@_);
    return $self;
}


sub add_entry {
    my $self = shift;
    push @{ $self->{entries} }, [@_];
}


#===================================
sub entries {
#===================================
    my $self = shift;
    return $self->{entries};
}


#===================================
sub clear {
#===================================
    my $self = shift;
    $self->{entries} = [];
}


sub file_types {
    die "Please override sub file_types() to return "
        . "a list of recognised file extensions, or regexes";
}


sub extract {
    die "Please override sub extract()";
}

sub _compile_file_types {
    my $self = shift;
    my @file_types
        = ref $_[0] eq 'ARRAY'
        ? @{ shift @_ }
        : @_;
    @file_types = $self->file_types
        unless @file_types;

    my @checks;
    if ( grep { $_ eq '*' } @file_types ) {
        $self->{file_checks} = [ sub {1} ];
        return;
    }
    foreach my $type (@file_types) {
        if ( ref $type eq 'CODE' ) {
            push @checks, $type;
            next;
        }
        else {
            my $regex
                = ref $type
                ? $type
                : qr/^.*\.\Q$type\E$/;
            push @checks, sub { $_[0] =~ m/$regex/ };
        }
    }
    $self->{file_checks} = \@checks;
}


sub known_file_type {
    my $self = shift;
    my ( $name, $path ) = fileparse( shift @_ );
    foreach my $check ( @{ $self->{file_checks} } ) {
        return 1 if $check->( $name, $path );
    }
    return 0;
}


1;

__END__