File Coverage

blib/lib/Linux/GetPidstat.pm

Criterion	Covered	Total	%
statement	57	58	98.2
branch	16	18	88.8
condition	11	15	73.3
subroutine	11	11	100.0
pod	1	2	50.0
total	96	104	92.3

package Linux::GetPidstat;
use 5.008001;
use strict;
use warnings;

our $VERSION = "0.09";

use Carp;
use Time::Piece::MySQL;

use Linux::GetPidstat::Reader;
use Linux::GetPidstat::Collector;
use Linux::GetPidstat::Writer;

sub new {
    my $class = shift;
    bless {}, $class;
}

sub run {
    my ($self, %args) = @_;

    $self->_validate_args(%args);

    my $pid_dir_path = $args{pid_dir};
    my $datetime;
    unless (length $args{datetime}) {
        $datetime = localtime;
    } else {
        $datetime = localtime->from_mysql_datetime($args{datetime});
    }

    my $program_pid_mapping = Linux::GetPidstat::Reader->new(
        pid_dir       => $pid_dir_path,
        include_child => $args{include_child},
        max_child_limit => $args{max_child_limit},
    )->get_program_pid_mapping;

    unless (@$program_pid_mapping) {
        croak "Not found pids in pid_dir: $pid_dir_path";
    }

    my $ret_pidstats = Linux::GetPidstat::Collector->new(
        interval => $args{interval},
        count    => $args{count},
    )->get_pidstats_results($program_pid_mapping);

    unless (%$ret_pidstats) {
        croak "Failed to collect metrics";
    }

    Linux::GetPidstat::Writer->new(
        res_file                   => $args{res_file},
        mackerel_metric_type       => $args{mackerel_metric_type},
        mackerel_api_key           => $args{mackerel_api_key},
        mackerel_service_name      => $args{mackerel_service_name},
        mackerel_metric_key_prefix => $args{mackerel_metric_key_prefix},
        mackerel_host_id           => $args{mackerel_host_id},
        now                        => $datetime,
        dry_run                    => $args{dry_run},
    )->output($ret_pidstats);
}

sub _validate_args {
    my ($self, %args) = @_;

    unless (length $args{pid_dir}) {
        croak("pid_dir required");
    }

    my $mackerel_metric_type  = $args{mackerel_metric_type};
    my $mackerel_api_key      = $args{mackerel_api_key};
    my $mackerel_service_name = $args{mackerel_service_name};
    if (length $mackerel_metric_type && $mackerel_metric_type eq "service") {
        unless (length $mackerel_api_key &&
                length $mackerel_service_name) {
            croak("when mackerel_metric_type is 'service', mackerel_[api_key|service_name] are required");
        }
        return;
    }

    my $mackerel_host_id = $args{mackerel_host_id};
    if (length $mackerel_metric_type && $mackerel_metric_type eq "host") {
        unless (length $mackerel_api_key &&
                length $mackerel_service_name &&
                length $mackerel_host_id) {
            croak("when mackerel_metric_type is 'host', mackerel_[api_key|service_name|host_id] are required");
        }
        return;
    }

    my $res_file = $args{res_file};
    if (length $res_file) {
        return;
    }

    croak("res_file or mackerel_metric_type required");
}

1;
__END__