File Coverage

blib/lib/LaTeXML/Common/Object.pm

Criterion	Covered	Total	%
statement	10	12	83.3
branch			n/a
condition			n/a
subroutine	4	4	100.0
pod			n/a
total	14	16	87.5

# /=====================================================================\ #
# |  LaTeXML::Common::Object                                            | #
# | Abstract base class for LaTeXML objects                             | #
# |=====================================================================| #
# | Part of LaTeXML:                                                    | #
# |  Public domain software, produced as part of work done by the       | #
# |  United States Government & not subject to copyright in the US.     | #
# |---------------------------------------------------------------------| #
# | Bruce Miller                         #_#     | #
# | http://dlmf.nist.gov/LaTeXML/                              (o o)    | #
# \=========================================================ooo==U==ooo=/ #
package LaTeXML::Common::Object;
use strict;
use warnings;
use LaTeXML::Global;
use XML::LibXML;    # Need XML_xxx constants!
use base qw(Exporter);
our @EXPORT = (
  qw(&Stringify &ToString &Revert &Equals),
);

#======================================================================
# Exported generic functions for dealing with LaTeXML's objects
#======================================================================

my %NOBLESS = map { ($_ => 1) } qw( SCALAR HASH ARRAY CODE REF GLOB LVALUE);    # [CONSTANT]

# Since the next two are used in debugging and error messages,
# be careful to avoid recursive errors
sub Stringify {
  my ($object) = @_;
  my $string = eval {
    local $LaTeXML::IGNORE_ERRORS = 1;
    if    (!defined $object)          { return 'undef'; }
    elsif (!ref $object)              { return $object; }
    elsif ($NOBLESS{ ref $object })   { return "$object"; }
    elsif ($object->can('stringify')) { return $object->stringify; }
    # Have to handle LibXML stuff explicitly (unless we want to add methods...?)
    elsif ($object->isa('XML::LibXML::Node')) {
      if ($object->nodeType == XML_ELEMENT_NODE) {
        my $model = $STATE && $STATE->getModel;
        my $tag = ($model ? $model->getNodeQName($object)
          : $object->nodeName);
        my $attributes = '';
        foreach my $attr ($object->attributes) {
          my $name = $attr->nodeName;
          my $val  = $attr->getData;
          $val = substr($val, 0, 30) . "..." if length($val) > 35;
          $attributes .= ' ' . $name . "=\"" . $val . "\""; }
        return "<" . $tag . $attributes . ($object->hasChildNodes ? ">..." : "/>");
      }
      elsif ($object->nodeType == XML_TEXT_NODE) {
        return "XMLText[" . $object->data . "]"; }
      elsif ($object->nodeType == XML_DOCUMENT_NODE) {
        return "XMLDocument[" . $$object . "]"; }
      elsif ($object->nodeType == XML_DOCUMENT_FRAG_NODE) {
        return "XMLFragment[" . join('', map { Stringify($_) } $object->childNodes) . "]"; }
      else { return "$object"; } }
    else { return "$object"; } };
  return (defined $string ? $string : overload::StrVal($object)); }    # Fallback, if errors

sub ToString {
  my ($object) = @_;
  return '' unless defined $object;
  my $string = eval {
    local $LaTeXML::IGNORE_ERRORS = 1;
    my $r;
    return (($r = ref $object) && !$NOBLESS{$r} ? $object->toString : "$object"); };
  return (defined $string ? $string : overload::StrVal($object)); }    # Fallback, if errors

# Just how deep of an equality test should this be?
sub Equals {
  my ($a, $b) = @_;
  return 1 if !(defined $a) && !(defined $b);    # both undefined, equal, I guess
  return 0 unless (defined $a) && (defined $b);  # else both must be defined
  my $refa = (ref $a) || '_notype_';
  my $refb = (ref $b) || '_notype_';
  return 0 if $refa ne $refb;                    # same type?
  return $a eq $b if ($refa eq '_notype_') || $NOBLESS{$refa};    # Deep comparison of builtins?
        # Special cases? (should be methods, but that embeds State knowledge too low)

  if ($refa eq 'LaTeXML::Core::Token') {    # Check if they've been \let to the same defn.
    my $defa = $STATE->lookupMeaning($a) || $a;
    my $defb = $STATE->lookupMeaning($b) || $b;
    return $defa->equals($defb); }
  return $a->equals($b); }                  # semi-shallow comparison?

# Reverts an object into TeX code, as a Tokens list, that would create it.
# Note that this is not necessarily the original TeX.
sub Revert {
  my ($thing) = @_;
  no warnings 'recursion';
  return (defined $thing
    ? (ref $thing ? map { $_->unlist } $thing->revert
      : LaTeXML::Core::Token::Explode($thing))    # Ugh!!
    : ()); }

#======================================================================
# LaTeXML Object
#  Base object for all LaTeXML Objects;
# Defines basic default methods for comparison, printing
# Tried to use overloading, but the Magic methods lead to hard-to-find
# (and occasionally quite serious) performance issues -- at least, if you
# try to have stringify do too much.
#======================================================================

sub stringify {
  my ($object) = @_;
  my $string = "$object"; overload::StrVal($object);
  $string =~ s/^LaTeXML:://;
  $string =~ s/=(SCALAR|HASH|ARRAY|CODE|REF|GLOB|LVALUE|)\(/\[@/;
  $string =~ s/\)$/\]/;
  return $string; }

sub toString {
  my ($self) = @_;
  return $self->stringify; }

sub toAttribute {
  my ($self) = @_;
  return $self->toString; }

sub equals {
  my ($a, $b) = @_;
  return "$a" eq "$b"; }    # overload::StrVal($a) eq overload::StrVal($b); }

sub notequals {
  my ($a, $b) = @_;
  return !($a->equals($b)); }

sub isaToken      { return 0; }
sub isaBox        { return 0; }
sub isaDefinition { return 0; }

# These should really only make sense for Data objects within the
# processing stream.
# Defaults (probably poor)
sub beDigested {
  my ($self) = @_;
  return $self; }

sub beAbsorbed {
  my ($self, $document) = @_;
  return $document->openText($self->toString, $document->getNodeFont($document->getElement)); }

sub unlist {
  my ($self) = @_;
  return $self; }

#**********************************************************************
1;

__END__