File Coverage

blib/lib/Iterator/File/Line.pm

Criterion	Covered	Total	%
statement	42	49	85.7
branch	14	18	77.7
condition			n/a
subroutine	10	11	90.9
pod	5	5	100.0
total	71	83	85.5

# $Id: /mirror/perl/Iterator-File-Line/trunk/lib/Iterator/File/Line.pm 42691 2008-02-25T01:07:47.310615Z daisuke  $
#
# Copyright (c) 2008 Daisuke Maki
# All rights reserved.

package Iterator::File::Line;
use strict;
use warnings;
use base qw(Class::Accessor::Fast);

our $VERSION = '0.00002';

__PACKAGE__->mk_accessors($_) for qw(source filter chomp encoding eol);

sub new
{
    my $class = shift;
    my %args  = @_;

    if ( $args{filename} ) {
        return $class->new_from_file( %args );
    } elsif ($args{fh}) {
        return $class->new_from_fh( %args );
    }

    die "Must provide filename or file handle";
}

sub new_from_file
{
    my $class = shift;
    my %args  = @_;

    my $filename = delete $args{filename};
    open(my $fh, '<', $filename) or die "Could not open $filename";

    $class->new_from_fh( %args, fh => $fh );
}

sub new_from_fh
{
    my $class = shift;
    my %args  = @_;
    my $fh = delete $args{fh};

    my $self = $class->SUPER::new( {
        filter   => $args{filter},
        chomp    => exists $args{chomp} ? $args{chomp} : 1,
        eol      => $args{eol},
        encoding => $args{encoding},
        source   => $fh,
    } );

    $self->_setup_layers();
    return $self;
}

sub next
{
    my $self = shift;
    my $fh   = $self->source;
    my $line = <$fh>;
    return  undef unless defined $line;
    chomp $line if $self->chomp;
    return $self->filter ? $self->filter->( $line ) : $line;
}

sub rewind
{
    my $self = shift;
    my $fh   = $self->source;
    seek($fh, 0, 0);
}

sub _setup_layers
{
    my $self = shift;
    my $fh   = $self->source;

    my @layers = ('', 'raw');
    if ($self->eol) {
        push @layers, sprintf('eol(%s)', $self->eol );
    }

    if ($self->encoding) {
        push @layers, sprintf('encoding(%s)', $self->encoding);
    }

    binmode($fh, join(':', @layers));
}

1;

__END__