File Coverage

blib/lib/Imager/Filter/Bakumatsu.pm

Criterion	Covered	Total	%
statement	12	24	50.0
branch	0	4	0.0
condition			n/a
subroutine	4	5	80.0
pod	0	1	0.0
total	16	34	47.0

package Imager::Filter::Bakumatsu;
use strict;
use warnings;
our $VERSION = '0.04';

use Imager;
use File::ShareDir 'dist_file';

my $texture = dist_file('Imager-Filter-Bakumatsu', 'BakumatsuTexture.png');

Imager->register_filter(
    type     => 'bakumatsu',
    callsub  => \&vintage,
    callseq  => [],
    defaults => {
        overlay_image => $texture,
    },
);

sub vintage {
    my %opt  = @_;
    my $self = delete $opt{imager};
    my $work = $self;

    $work = $work->convert(
        matrix => [
            [ 1.7,   0,   0, 0 ],
            [   0, 1.7,   0, 0 ],
            [   0,   0, 1.7, 0 ],
        ],
    );

    $work->filter(
        type      => 'contrast',
        intensity => 1.2,
    );

    $work->filter(
        type => 'autolevels',
        lsat => 0.3,
        usat => 0.3,
    );

    $work = $work->convert(
        matrix => [
            [ 1 / 4, 1 / 2, 1 / 8, 0 ],
            [ 1 / 4, 1 / 2, 1 / 8, 0 ],
            [ 1 / 4, 1 / 2, 1 / 8, 0 ],
        ],
    );

    $work->rubthrough(
        src => do {
            my $overlay = Imager->new;
               $overlay->read(file => $opt{overlay_image})
                or die $overlay->errstr;

            $overlay = $overlay->scale(
                xpixels => $work->getwidth,
                ypixels => $work->getheight,
                type    => 'nonprop'
            );
        },
    ) or die $work->errstr;

    $self->{IMG} = delete $work->{IMG};
}

1;
__END__