File Coverage

blib/lib/IPC/Open2/Simple.pm

Criterion	Covered	Total	%
statement	32	36	88.8
branch	2	4	50.0
condition			n/a
subroutine	7	7	100.0
pod	1	1	100.0
total	42	48	87.5

package IPC::Open2::Simple;

use strict;
use warnings;
use IO::Handle;
use IPC::Open2;
use Exporter 'import';
use Carp;

our $VERSION = '0.01';
our @EXPORT_OK = qw(open2s);

sub open2s {
	my ($out, $in, @cmd) = @_;

	# Sanity checks
	for my $arg ($out, $in) {
		unless (ref($arg) eq 'SCALAR') {
			carp "open2s: \$out and \$in both must be a scalarref";
			return undef;
		}
	}
	unless (@cmd) {
		carp "open2s: empty command line";
		return undef;
	}

	my ($fh_out, $fh_in) = (IO::Handle->new, IO::Handle->new);

	my $pid = open2($fh_out, $fh_in, @cmd);
	# open2() will die if it cannot fork, so we
	# do not need to check $pid here.

	# Pass the input
	$fh_in->print($$in);
	$fh_in->close;

	# Read the output
	{
		local $/;
		until ($fh_out->eof) {
			$$out .= $fh_out->getline;
		}
	}

	# Wait for the child's tragic death
	waitpid $pid, 0;

	return $? >> 8;
}

1;

__END__