File Coverage

blib/lib/IO/File/CompressOnClose/Zip.pm

Criterion	Covered	Total	%
statement	37	39	94.8
branch	8	12	66.6
condition			n/a
subroutine	9	9	100.0
pod	2	2	100.0
total	56	62	90.3

#
# $Id: Zip.pm,v 1.1 2003/12/28 00:15:15 james Exp $
#

=head1 NAME

IO::File::CompressOnClose::Zip - Zip compression for
IO::File::CompressOnClose

=head1 SYNOPSIS

 use IO::File::AutoCompress::Zip;
 my $file = IO::File::CompressOnClose::Zip->new('>foo');
 print $file "foo bar baz\n";
 $file->close;  # file will be compressed to foo.zip

=cut

package IO::File::CompressOnClose::Zip;

use strict;
use warnings;

use vars                        qw|$VERSION @ISA|;

@ISA                          = qw|IO::File::CompressOnClose|;
$VERSION                      = $IO::File::CompressOnClose::VERSION;

use Archive::Zip                qw|:ERROR_CODES|;
use Carp                        qw|croak|;
use IO::File;
use IO::File::CompressOnClose;


# compress using zip
sub compress
{

    my($self, $src_file, $dst_file) = @_;

    # tack on a .gz extension
    unless( $dst_file ) {
        $dst_file = "$src_file.zip";
    }

    # create a new archive
    my $zip = Archive::Zip->new
        or croak("cannot instantiate Archive::Zip object");

    # figure out the name of the member in the archive
    my $member_name;
    unless( $member_name = $self->member_filename ) {
        require File::Basename;
        $member_name = File::Basename::basename($src_file);
    }

    # add the source file to the archive
    unless( $zip->addFile( $src_file, $member_name ) ) {
        croak("cannot add $src_file to archive");
    }

    # write out the archive
    unless( AZ_OK == $zip->writeToFileNamed( $dst_file ) ) {
        croak("cannot write archive $dst_file");
    }

}


# accessor methods
sub member_filename
{

    my($self, $newval) = @_;
    my $oldval = ${*$self}->{member_filename};
    ${*$self}->{member_filename} = $newval if( @_ > 1 );
    return $oldval;

}

# keep require happy
1;


__END__